[三流君] −−＞
[ＡＳＰで遊ぶ、失敗する] −−＞
[バックナンバー一覧]
−−＞ No.047 いろいろな削除処理で遊んでみた（笑）
いろいろな削除処理で遊んでみた（笑）
本文(発行内容)
＜いろいろな削除処理で遊んでみた（笑）＞
こんにちは、三流プログラマーのＫｅｎ３です。
今回は、データの削除処理で遊んでみます。
タイトルいろいろなとなっているけど、数パターンです（笑）
※誇大タイトルかなぁ
拾い読みして、何かの参考となれば幸いです。
/*
* １．削除処理を振りかえってみた
*/
[No.32 SQL DELETE文でデータを削除してみた]
http://www.ken3.org/backno/backno_asp07.html#32
で、SQL DELETE文を発行してみました。
基本は、
IDが５番のデータを削除するには、
Delete From KANSOU Where ID = 5
と
Delete From テーブル Where 条件
のＳＱＬ文を発行します。
削除したいデータを特定するために、IDフィールド（自動連番の）を使っていました。
元データを一覧表示して、
１行単位で、
フォームの隠し項目でIDを管理、
削除ボタンが押されたら削除用のＡＳＰを呼び、
呼ばれた側でIDを条件にした削除のSQL DELETE文を発行してました。
http://www.ken3.org/cgi-bin/test/test032-1.asp
でデータを選択して、test032-2.aspで削除処理を行っていました。
※選択・削除実行と２つのＡＳＰファイルでした。
/*
* ２．２つの処理を１つにまとめてみた
*/
別に、ムリにまとめなくてもよいのですが、
データ選択処理と削除処理を１つにまとめてみました。
まとめるポイントは、
頭で、削除するＩＤが送られて来たら削除するSQL文を発行。
データを一覧表示して削除ボタンを作り、ACTIONで自分自身を呼びます。
いつもながら、わかりにくい日本語だね。
そうですよね、、、では、いつものサンプル紹介から。
データベース名:db029.mdb
テーブル名:KANSOU
フィールド
ID オートナンバー型
F_KUBUN テキスト型 ASP,VBA,GUCHI,24Hと４つの区分
F_NO 整数型 0:は全体に対して、１〜はＸ話にする
F_MEMO テキスト型 一言メッセージ
WriteTime 日付型 書き込み日付
http://www.ken3.org/cgi-bin/test/test047-1.asp
でテスト実行できます。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>削除データの選択とSQL DELETE文の発行</title>
</head>
<body>
<h2>削除データの選択とSQL DELETE文の発行</h2>
test047-1.asp<br>関連項目
<A href="test029-1.asp">データの登録（SQL INSERT文でテストデータを増やす）</a><br>
<%
'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
Set db=Server.CreateObject("ADODB.Connection")
'データアクセスにはJet.OLEDB.4.0を使うことを設定
db.Provider = "Microsoft.Jet.OLEDB.4.0"
'次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
db.ConnectionString = Server.MapPath("db029.mdb")
'やっとデータベースを開ける
db.open
'ＩＤが送られてきたかチェックする
If IsEmpty(Request.Form("DELETE_ID")) = False Then 'IDが在りの時
'IDを条件にSQL DELETE文を作る
strSQL = "DELETE From KANSOU " '感想(KANSOU)テーブルを削除するので
strSQL = strSQL & " Where ID=" & Request.Form("DELETE_ID")
Response.Write "<hr>データ削除IDは" & Request.Form("DELETE_ID")
'オマケで画面にデータ表示
Response.Write "<br>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'SQL文の発行
db.Execute(strSQL)
End If
'
'データ表示と削除ボタン生成
'
'一覧表示用のSQL文を作る
strSQL = "Select * From KANSOU " '感想(KANSOU)テーブルから全項目(*)セレクト
strSQL = strSQL & "ORDER BY WriteTime DESC" '並べ替えは時間の降順
'オマケで画面にデータ表示
Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'お約束のレコードセットの作成 SQL文の発行
Set rs = db.Execute(strSQL)
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しをバカっぽく、そのまま書き込む
Response.Write "<TR>"
Response.Write "<TD>アクション</TD>"
Response.Write "<TD>日付</TD>"
Response.Write "<TD>区分</TD>"
Response.Write "<TD>NO.</TD>"
Response.Write "<TD>感想</TD>"
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する、行開始のタグ＜ＴＲ＞
'フォームを作成する ※ACTIONで自分自身を呼ぶ
Response.Write "<TD><FORM ACTION='test047-1.asp' METHOD='POST'>"
'IDを隠し項目(DELETE_ID)にする
Response.Write "<INPUT type='hidden' NAME='DELETE_ID' VALUE='"
Response.Write rs.Fields.Item("ID") & "'>"
'ボタンは普通に作成する
Response.Write "<INPUT TYPE='submit' VALUE='削除'>"
Response.Write "</FORM></TD>"
'中身を表示
Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
If rs.Fields.Item("F_NO") = 0 Then '0の全体かチェック
Response.Write "<TD>全体</TD>"
Else
Response.Write "<TD>" & rs.Fields.Item("F_NO") & "</TD>" 'NO表示
End If
Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
Response.Write "</TR>"
'次のレコードにポインタを移動する
rs.MoveNext 'これを忘れると悲惨なことに、、、
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
rs.Close '開いていたレコードセットを閉じる
db.Close 'データベースも閉じようよ
Set db = Nothing 'お行儀よくオブジェクトも開放しましょう
%>
<HR>
終了です。<br>
<A href="test029-1.asp">データの登録（テストデータを増やす、消したら書いてね）</a><br>
</body>
</html>
処理の解説とポイント
~~~~~~~~~~~~~~~~~~~~
・データベースオープン（接続）
・IsEmptyで送られたデータをチェック
データ在りの時、DELETE文の発行
・データ一覧の表示
IDを隠し項目として自分自身を呼ぶ削除ボタンの作成
簡単な流れはこんな感じです。
http://www.ken3.org/cgi-bin/test/test047-1.asp
が初回に呼ばれた時は、
If IsEmpty(Request.Form("DELETE_ID")) = False Then
のチェックで何もしないで、
２回目に呼ばれた時に、削除のＳＱＬを発行してます。
あとは、隠し項目でDELETE_IDを持った自分自身を呼ぶ削除のボタンを作成してます。
'フォームを作成する ※ACTIONで自分自身を呼ぶ
Response.Write "<TD><FORM ACTION='test047-1.asp' METHOD='POST'>"
'IDを隠し項目(DELETE_ID)にする
Response.Write "<INPUT type='hidden' NAME='DELETE_ID' VALUE='"
Response.Write rs.Fields.Item("ID") & "'>"
'ボタンは普通に作成する
Response.Write "<INPUT TYPE='submit' VALUE='削除'>"
Response.Write "</FORM></TD>"
type='hidden'で隠し項目に設定してます。
/*
* ３．複数のデータを削除してみたい
*/
まぁ、なんとなく出来たんだけど（オイオイそんなんでいいの？）
ボタンを押したら該当データの削除から、
今度は、チェックボックスを使用して
チェックされたデータ複数を削除する処理に挑戦してみたいと思います。
[No.45 HTML FORM INPUT TYPE="CHECKBOX" チェックボックスの入力]
http://www.ken3.org/backno/backno_asp10.html#45
で、
チェックボックスから値を受取る処理を数パターン書きました。
下記のようにチェックボックスなのに１つの項目にすると、
<INPUT TYPE="CHECKBOX" NAME="kibou" VALUE="HTML">HTMLから詳しく丁寧に<BR>
<INPUT TYPE="CHECKBOX" NAME="kibou" VALUE="VBScript">VBScriptをもっと詳しく<BR>
<INPUT TYPE="CHECKBOX" NAME="kibou" VALUE="GAME">ゲーム作ろうよ<BR>
http://www.ken3.org/cgi-bin/test/test045-1.asp
で実際にテストしてもらうとわかりますが、
項目名 値
kibou HTML, VBScript, GAME
と
HTML, VBScript, GAME
選択された項目の値をカンマ区切りで受取れます。
[No.46 SQL文 SELECT WHERE句でIN演算子を使用して複数条件を選択する]
http://www.ken3.org/backno/backno_asp10.html#46
でWHERE句でIN演算子を使用して複数条件の選択方法を書きました
IN演算子を使用して、
Select * From KANSOU
Where F_KUBUN IN ('ASP', 'VBA', 'GUCHI', '24H')
ORDER BY WriteTime DESC
とSQL文を発行しました。
読者の心の声：あっ、組み合わせれば出来そう、もうメルマガ見なくてイイヤ
なんて声が聞こえたかどうかはわかりませんが、
組み合わせれば出来そうです。
ＩＤの選択方法をチェックボックスに直し、
削除のDELETE文をWhere ID IN ( 99, 99 ... )に対応させる。
削除IDの94, 93, 92を受取り、
DELETE From KANSOU Where ID IN (94, 93, 92)
と発行すれば複数データを削除できます。
下記、修正した複数削除のサンプルです。
http://www.ken3.org/cgi-bin/test/test047-2.asp
でテストできます。遊んでみてください。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>複数の削除データ選択とSQL DELETE文の発行</title>
</head>
<body>
<h2>複数の削除データ選択とSQL DELETE文の発行</h2>
test047-2.asp<br>関連項目
<A href="test029-1.asp">データの登録（SQL INSERT文でテストデータを増やす）</a><br>
<%
'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
Set db=Server.CreateObject("ADODB.Connection")
'データアクセスにはJet.OLEDB.4.0を使うことを設定
db.Provider = "Microsoft.Jet.OLEDB.4.0"
'次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
db.ConnectionString = Server.MapPath("db029.mdb")
'やっとデータベースを開ける
db.open
'ＩＤが送られてきたかチェックする
If IsEmpty(Request.Form("DELETE_ID")) = False Then 'IDが在りの時
'IDを条件にSQL DELETE文を作る
strSQL = "DELETE From KANSOU " '感想(KANSOU)テーブルを削除するので
'複数項目に対応するために、Where ID INを使用する
strSQL = strSQL & " Where ID IN (" & Request.Form("DELETE_ID") & ")"
Response.Write "<hr>データ削除IDは" & Request.Form("DELETE_ID")
'オマケで画面にデータ表示
Response.Write "<br>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'SQL文の発行
db.Execute(strSQL)
End If
'
'データ表示と削除ボタン生成
'
'一覧表示用のSQL文を作る
strSQL = "Select * From KANSOU " '感想(KANSOU)テーブルから全項目(*)セレクト
strSQL = strSQL & "ORDER BY WriteTime DESC" '並べ替えは時間の降順
'オマケで画面にデータ表示
Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'お約束のレコードセットの作成 SQL文の発行
Set rs = db.Execute(strSQL)
'フォームを作成する ※ACTIONで自分自身を呼ぶ
Response.Write "<TD><FORM ACTION='test047-2.asp' METHOD='POST'>"
Response.Write "削除したいデータにチェックを入れ実行ボタンを押してください<br>"
Response.Write "<INPUT TYPE='submit' VALUE='削除実行'>"
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しをバカっぽく、そのまま書き込む
Response.Write "<TR>"
Response.Write "<TD>アクション</TD>"
Response.Write "<TD>日付</TD>"
Response.Write "<TD>区分</TD>"
Response.Write "<TD>NO.</TD>"
Response.Write "<TD>感想</TD>"
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する、行開始のタグ＜ＴＲ＞
'CHECKBOX DELETE_ID 作成
Response.Write "<TD><INPUT type='CHECKBOX' NAME='DELETE_ID' VALUE='"
Response.Write rs.Fields.Item("ID") & "'></TD>"
'データの中身を表示
Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
If rs.Fields.Item("F_NO") = 0 Then '0の全体かチェック
Response.Write "<TD>全体</TD>"
Else
Response.Write "<TD>" & rs.Fields.Item("F_NO") & "</TD>" 'NO表示
End If
Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
Response.Write "</TR>"
'次のレコードにポインタを移動する
rs.MoveNext 'これを忘れると悲惨なことに、、、
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
Response.Write "<INPUT TYPE='submit' VALUE='削除実行'>"
Response.Write "<FORM>"
rs.Close '開いていたレコードセットを閉じる
db.Close 'データベースも閉じようよ
Set db = Nothing 'お行儀よくオブジェクトも開放しましょう
%>
<HR>
終了です。<br>
<A href="test029-1.asp">データの登録（テストデータを増やす、消したら書いてね）</a><br>
</body>
</html>
ポイント解説
~~~~~~~~~~~~
strSQL = "DELETE From KANSOU " '感想(KANSOU)テーブルを削除するので
'複数項目に対応するために、Where ID INを使用する
strSQL = strSQL & " Where ID IN (" & Request.Form("DELETE_ID") & ")"
普通に、Where ID INとしただけでした。
次はチェックボックスの作成です、
'CHECKBOX DELETE_ID 作成
Response.Write "<TD><INPUT type='CHECKBOX' NAME='DELETE_ID' VALUE='"
Response.Write rs.Fields.Item("ID") & "'></TD>"
と、type='CHECKBOX'に変更しただけです。
意外と簡単にできましたね。
http://www.ken3.org/cgi-bin/test/test047-2.asp
でテストできます。遊んでみてください。
/*
* ４．終わりの挨拶 ＜／ＨＴＭＬ＞
*/
今回は、
削除処理のパターンを２つ書きました。
ポイントは、
・自分自身を呼んで処理をまとめる
・WHERE句でIN演算子を使用して複数条件を削除
ぐらいかなぁ。
まぁ、複数削除はあまり無いと思いますが、
複数選択、処理実行のサンプルになれば幸いです。
素朴な疑問あったら、気軽に、
メール、掲示板に書き込んでくださいね。
掲示板 : http://www.ken3.org/asp/bbs-asp.html
ＡＳＰ、ＶＢＳｃｒｉｐｔ勉強中の三流プログラマーのＫｅｎ３でした。
----------------------------------
関連項目(ただのバックナンバー紹介)
----------------------------------
[No.32 SQL DELETE文でデータを削除してみた]
http://www.ken3.org/backno/backno_asp07.html#32
で、SQL DELETE文を発行してみました。
[No.45 HTML FORM INPUT TYPE="CHECKBOX" チェックボックスの入力]
http://www.ken3.org/backno/backno_asp10.html#45
で、チェックボックスから値を受取る処理を数パターン書きました。
[No.46 SQL文 SELECT WHERE句でIN演算子を使用して複数条件を選択する]
http://www.ken3.org/backno/backno_asp10.html#46
でWHERE句でIN演算子を使用して複数条件の選択方法を書きました
フィードバック
ASP系の→[掲示板]←を覗く、質問を書き込む
評価・感想
三流君の主なリンク先
[アクセスランキング]
[サイトマップ]
[リンク先・相互リンク先など]
Ken3の日記(weblog) --
[広告・副収入系]
[プログラマー業務の愚痴]
[VBA系の話題]
[ASP系の話題]
[コンビニ系ネタ]
[その他]
その他 宣伝広告