三流君 ＶＢＡで楽しくプログラミング(Excel/Access VBAの解説/サンプルです)
[VBA系のバックナンバー]
[質問/感想 掲示板]
[メルマガ登録/解除]
[VBA系 TOP]
[サイトマップ]
| No.70 |
2003/05/02
InternetExplorer.application .document.all(0).innerHTML |
[ページTOPへ戻る] |
|
＜InternetExplorer.application .document.all(0).innerHTML＞
こんにちは、三流プログラマーＫｅｎ３です。
今回は、
掲示板に質問があった、
彼女のすべてをのぞきたい、全てを取得したい。
じゃなくって、
IEでＨＴＭＬソースすべてを取得したい
です。
溜まっているオヤジギャグは置いといて、はじめますか？
（何が溜まっているって？駄目だよ変な想像したら・・・
想像したのがたぶんあたりだけど、と回答を書かないのがＫｅｎ３流の文章）
/*
* １．今回のキッカケ
*/
掲示板、
http://www.ken3.org/cgi-bin/bbs/vba/wforum.cgi?mode=allread&no=111&page=0
に来た質問です。※何か質問あったら遠慮なく、回答遅いけど。
---
>投稿時間：2003/05/02(Fri) 19:13
>投稿者名：nori
>タイトル：はじめまして
>
>はじめまして。
>早速ですが、vba解説のNo.50 IE起動に関する質問があります。
>
>Dim objIE As ObjectobjIE.Navigate "http://..."
>Dim strHTML As String
>strHTML = objIE.document.body.innerHTML
>
>でhtmlソースを取り出す事は出来ましたが、<body>内しか取り出せません。
>objIE.document.title
>で<title>内も取り出せることは分かりましたが、<head>内すべてを取り出す事
>は出来るのでしょうか？
>htmlにあまり詳しくないもので、解決しません。そもそも、<html>内は取り出
>せなくて当たり前なのでしょうか。愚問かもしれませんが、お返事よろしくお
>願いします。
---
さて、やりたいことを整理して、
と思ったら、もう整理されてますね。
・<head>内のソースを取得したい
・htmlの全てのソースを取得したいかぁ。
/*
* ２．IEオブジェクトの中身を探れ(手ごわい彼女の心の中？)
*/
[No.50 IE起動 CreateObject("InternetExplorer.application")]
( http://www.ken3.org/backno/backno_vba11.html#50 を参照)
では、IEの起動方法を書きました。
[No.52 InternetExplorer.application .document.body.innerText]
( http://www.ken3.org/backno/backno_vba11.html#52 を参照)
では、
彼女（オブジェクト）の中身を探る方法を少し書きました。
それにしても、階層が深いです。
テーブル系のオブジェクトを探すが、なかなか見つからない。
（女の子じゃなくって、ＩＥの心の中は複雑なのね、、、）
女心を探るのは下手だけど、オブジェクトの中身見るのは少しできるよね？
なんて、馬鹿なこと言ってないで、ブレークポイントをはって、止めます。
いやらしい目で頭から探っていくと（ほんとは真剣な目ですよ）
objIE.document.の下に、
.allなんてそれらしいのあるじゃないですか。
読者の人に見せたくないニャっとした顔で、
? objIE.document.all(0).innerHTML
とやってみると、ヘッダから情報が入ってました。
これを使えばなんとかできそうです。
下記Ｋｅｎ3がいやらしい目で見てたＩＥのオブジェクト
/*
* ３．.document.all(0).innerHTMLにいつも入っているのか？疑問だけど
*/
.document.all(0).innerHTML
と
０番目にいつも入っているのか？疑問だけど、
下記のようにテストしてＯＫでした。
Sub ie_get_html()
Dim objIE As Object 'ＩＥオブジェクト参照用
'インターネットエクスプローラーのオブジェクトを作る
Set objIE = CreateObject("InternetExplorer.application")
objIE.Visible = True '見えるようにする(お約束)
'ランキングのページに飛ぶ
objIE.Navigate "http://www.ken3.org/cgi-bin/lime/limemgr.cgi"
'表示されるまで待つ、10秒後にエラーを判断する
Dim time10 As Date '時刻格納用
time10 = DateAdd("s", 10, Now()) '現在から１０秒後を計算
Do While objIE.Busy = True 'ビジー、読み込み中の間
DoEvents
If time10 < Now() Then '１０秒経過したか？
MsgBox "タイムアウトです"
Exit Sub
End If
Loop
'HTMLソースを取出す
Dim strHTML As String
strHTML = objIE.document.all(0).innerHTML '変数に代入
MsgBox strHTML 'テスト表示
Debug.Print strHTML 'イミディエイトにも表示
End Sub |
彼女（ＩＥオブジェクト）の心の中は、複雑そうなので、
引き続き、いやらしい目じゃなくって真剣な目で（オイオイ）
調べてみたいと思います。
/*
* ４．おわりの挨拶
*/
今回のポイントは、
Ｋｅｎ３はエロオヤジだった
じっゃなくって
ＩＥのオブジェクトの中身の探り方でした。
No.52 InternetExplorer.application .document.body.innerText
http://www.ken3.org/backno/backno_vba11.html#52
にブレークポイント貼って、ウォッチで表示する画像があるので、
こっちを見ると美人をウォッチする方法がよくわかります（たぶん）
拾い読みして、
１つでも何かの参考となれば幸いです。
Ｅｘｃｅｌ／Ａｃｃｅｓｓ大好き、三流プログラマーＫｅｎ３でした。
※今日はふざけすぎました、解除しないでね。
＜IE操作 リンク先を取出す .Document.links(i).href＞
こんにちは、三流プログラマーＫｅｎ３です。
今回は、
IEで表示したＵＲＬのリンク先を取得したい
です。
/*
* １．今回のキッカケ
*/
前回の発行で、いろいろとＩＥの中身をいやらしく探ってたので、
自動巡回ソフト？の前準備、探りとして、
今回は、ＩＥで表示したページのリンクを探りたいと思います。
将来的には、自動エロ画像収集巡回、自動クリック、自動チケットアタック
を作りたいですね。
えっ、動機が不純だって？
不純な動機ほど気合が入るんですよ（それは変わり者のＫｅｎ３だけかな？）
/*
* ２．またまた、IEオブジェクトの中身を探れ(手ごわい彼女の心の中？)
*/
[No.52 InternetExplorer.application .document.body.innerText]
( http://www.ken3.org/backno/backno_vba11.html#52 を参照)
では、
彼女（オブジェクト）の中身を探る方法を少し書きました。
それにしても、階層が深いです。
テーブル系のオブジェクトを探すが、なかなか見つからない。
（女の子じゃなくって、ＩＥの心の中は複雑なのね、、、）
前回と同じ台詞でつまらないよ。
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
探り方がわかれば、あとは応用なので。
街中のナンパ同様、一回成功すれば、あとは応用なので
と、成功したこと無い私が書いても説得力無いけど（笑）
いつもの、馬鹿な前置きは置いといて、
いやらしい目で頭から探っていくと（ほんとは真剣な目ですよ）
デバックで止めて、変数の中身を見ます。
＊ウォッチ式を追加して、確認します。
? objIE.Document.links(1).outertext
[ 掲示板 ]
? objIE.Document.links(1).outerHTML
<A href="http://www.ken3.org/cgi-bin/bbs/vba/wforum.cgi"
target=_blank>[ 掲示板 ]</A>
.href .outertext .outerHTMLが使えそうなので、
~~~~~~~~~~~~~~~~~~~~~~~~~~~
今回使ってみます。
＊さらっと書いてるけど、ここまでたどり着くのにかなりかかっている（笑）
これを使えばなんとかできそうです。
/*
* ３．単体テストが完了、作成してみる
*/
単体のオブジェクト、プロパティの確認が終わったので、作成に取りかかります。
Sub ken3_url()
Dim objIE As InternetExplorer
Dim time10 As Date
Dim strURL As String
Dim i As Integer
On Error GoTo EMSG
Rows("13:1000").Select '結果の表示エリアをクリアする
Selection.Delete Shift:=xlUp
Set objIE = CreateObject("InternetExplorer.application")
objIE.GoHome
objIE.Visible = True
Do While objIE.Busy = True '起動まで待つ
DoEvents
Loop
nYLINE = 10 '10行目からチェックスタート
Cells(nYLINE, 1).Select
DoEvents
Cells(nYLINE, 2) = Now() 'テストで時間を代入
strURL = Trim(Cells(nYLINE, 1)) 'URL代入
objIE.Stop '読み込み停止(意味無いけど)
objIE.Navigate "" & strURL 'アドレスを渡し表示する
'読みこみ完了まで待つ
'20秒後を計算して、待つ
time10 = DateAdd("s", 20, Now())
Do While objIE.Busy = True
DoEvents
If time10 < Now() Then
Exit Do
End If
DoEvents
Loop
If objIE.Busy = True Then
Cells(nYLINE, 4) = "読み込みに失敗しました"
MsgBox "読み込みに失敗しました"
End If
'リンクを探す
nYLINE = 13 'セット位置を代入
'リンク数分まわす
For i = 0 To objIE.Document.links.Length - 1
Cells(nYLINE, "A") = "'" & objIE.Document.links(i).outerText
Cells(nYLINE, "B") = "'" & objIE.Document.links(i).href
Cells(nYLINE, "C") = "'" & objIE.Document.links(i).outerHTML
nYLINE = nYLINE + 1 'セット位置を＋1する
Next i
objIE.Quit 'ＩＥを閉じる
MsgBox "終了しました"
Exit Sub
EMSG:
Cells(nYLINE, 2) = "ERR"
objIE.Quit '
MsgBox "errが発生しました"
Exit Sub
End Sub |
ポイントは、
~~~~~~~~~~~~
objIE.Document.links.Length
でリンクの数を取得できるので、
'リンク数分まわす
For i = 0 To objIE.Document.links.Length - 1
Cells(nYLINE, "A") = "'" & objIE.Document.links(i).outerText
Cells(nYLINE, "B") = "'" & objIE.Document.links(i).href
Cells(nYLINE, "C") = "'" & objIE.Document.links(i).outerHTML
nYLINE = nYLINE + 1 'セット位置を＋1する
Next i
で、
objIE.Document.links(i).outerText
objIE.Document.links(i).href
objIE.Document.links(i).outerHTML
をそれぞれセットしてみました。
使えそうなプロパティあったかなぁ？
/*
* ４．おわりの挨拶
*/
今回は、ＩＥのリンク先を見るでした。
読者からの要望は、広告自動クリックソフトだったけど、
そこまでは、実力無かったので（笑）
No.52 InternetExplorer.application .document.body.innerText
http://www.ken3.org/backno/backno_vba11.html#52
にブレークポイント貼って、ウォッチで表示する画像があるので、
こっちを見ると美人(IE)をウォッチする方法がよくわかります（たぶん）
拾い読みして、
１つでも何かの参考となれば幸いです。
Ｅｘｃｅｌ／Ａｃｃｅｓｓ大好き、三流プログラマーＫｅｎ３でした。
※今日はふざけすぎました、解除しないでね。
＜文字列を日付型に変換、Cdateへの値の渡し方いろいろ？＞
こんにちは、三流プログラマーＫｅｎ３です。
今回は、
Cdate関数を利用して、文字列を日付型に変換してみます。
です。
/*
* １．今回のキッカケ
*/
よく、文字列８桁で日付のデータがあって、
これを日付型に代入したい、、ってことありますよね。
"20000804"を日付型に代入したい。
で、関数は、何を使えば、、と探すと、
Cdate(日付文字列) かDateSerial(year, month, day)
あと？（何かあるかなぁ？）
ここで、普通に、
strMOTO = "20000804"
基準日 = Cdate(strMOTO)
とやると、エラーになります。
Cdate("2000-08-04") やCdate("2000/08/04")
だと通ります。
う〜ん、日付をあらわす文字列にしないといけないんだぁ。。。
まぁ、いいやで、
/*
* ２．いろいろあるけど、自分にあった方法で、できればＯＫかなぁ。
*/
有名なMid関数を使って、やる方法を使っていました。
Sub test()
Dim strMOTO As String
Dim strWork As String
Dim 基準日 As Date
strMOTO = "20000804"
strWork = Mid(strMOTO, 1, 4) & "/" & Mid(strMOTO, 5, 2) & "/" & Mid(strMOTO, 7, 2)
基準日 = CDate(strWork)
MsgBox 基準日
End Sub |
ここで終ると、なんだ、知ってるよ、、
なので、
今日、拾ってきた（パクッタ）別の方法、
format関数を使って、下記みたいに書くこともできます
Sub test()
Dim strMOTO As String
Dim 基準日 As Date
strMOTO = "20000807"
基準日 = CDate(Format(strMOTO, "@@@@/@@/@@"))
MsgBox 基準日
End Sub |
まとめて、１行で書きましたが、
基準日 = CDate(Format(strMOTO, "@@@@/@@/@@"))
ポイントは、 /^^^^^^^^^^^
変換書式に＠を使うことです。
これで、１文字をあらわしてくれます。
＊応用で、 ５桁を4-1桁に変換は、
MsgBox Format("ABCDE", "@@@@-@")
とやって見て下さい。どうなるでしょうか？
話をもっとそらすと、
MsgBox Format("19990503", "YYYY/MM/DD")
はエラーになります。。。
人間様は、認識してるんだけど。。
~~~~~~~~~~
まぁ、使えれば、どちらでもいいや的な話でした。
＊個人的には、ｍｉｄで書くほうが好きかなぁ。
/*
* ３．関数は組み合わせって感じかなぁ
*/
a = Cdate("20030512")
で実行時エラー型が一致しませんが発生。
そんな時は、型をそろえてやるか、、と気軽に考えて、
Mid関数で切り出す、Format関数を使い形式をそろえる。
関数は組み合わせかなぁとフト思いました。
/*
* ４．おわりの挨拶
*/
今回は、
CDateで変換、フォーマットを合わせる方法いろいろ
の話でした。
拾い読みして、
１つでも何かの参考となれば幸いです。
Ｅｘｃｅｌ／Ａｃｃｅｓｓ大好き、三流プログラマーＫｅｎ３でした。
＜オブジェクトのループはFor Each In でループさせる＞
こんにちは、三流プログラマーＫｅｎ３です。
今回は、
オブジェクトやコレクションのループは、
いつものカウンタ添字じゃなく、
For Each In でループさせるです。
/*
* １．今回のキッカケ
*/
In message "リンク クリック",
しょうもさん wrote...
>[ ＶＢＡで楽しくプログラミング No.071 ] 2003/05/06 火曜日 より
>
>> 読者からの要望は、広告自動クリックソフトだったけど
>
>その名の通り、Clickメソッドが使えますよ。
>今回も、IHTMLElementオブジェクトを操っています。
>「Microsoft HTML Object Library」参照設定です。
>
>'-----------
> Dim objElement As IHTMLElement
> Dim strTempText As String
>
> For Each objElement In objIE.Document.all.tags(tagName:="a")
> strTempText = objElement.getAttribute _
> (strAttributeName:="href")
> Debug.Print strTempText
> If InStr(strTempText, "top10") Then
> objElement.Click
> Exit For
> End If
> Next
>'-----------
---
と、サンプルプログラムを読者より送ってもらった。
ありがたいなぁ。
人によってプログラムって書き方いろいろなんだけど、
私の悪いクセで、
For Each XXXX In XXXXX
のループを避ける傾向がある。。。
今回は、これについて、少々自分にお灸をすえる意味で発行します。
※一部の読者に人気かあるＩＥ使った不正なクリック処理は、
また今度ね。興味あるひとは直接メールで送ってね（爆）
/*
* ２．いろいろあるけど、自分にあった方法で、できればＯＫかなぁ。
*/
ループ処理って、よく聞くのが、
１〜１０までのループ
For n=1 To 10
Call 処理（BOX(n)）
Next n
なんて感じですよね。
これは、カウンタ変数ｎを使用して配列の変数を使う場合、
よくみかけるパターンですよね、配列のｎ番目を参照するって感じで。
オブジェクトやコレクションも配列になっているので、
オブジェクトのｎ番目を参照して、処理を行うって書き方ができます。
ちょっと前に作った、リンクを書き出す処理
[No.71 IE操作 リンク先を取出す .Document.links(i).href]
http://www.ken3.org/backno/backno_vba15.html#71
では、
'リンク数分まわす
For i = 1 To objIE.Document.links.Length
Cells(nYLINE, "A") = "'" & objIE.Document.links(i).outerText
Cells(nYLINE, "B") = "'" & objIE.Document.links(i).href
Cells(nYLINE, "C") = "'" & objIE.Document.links(i).outerHTML
nYLINE = nYLINE + 1 'セット位置を＋1する
Next i
と、
カウンタ変数ｉを１からobjIE.Document.links.Lengthの数回してました。
チョット、イメージ沸きにくいなぁ。
えっと、シートの名前を全て表示するには、
まずは、シートの数が必要、、
Debug.Print ActiveWorkbook.Sheets.Count
と、アクティブなブックのシートのカウントは？とプロパティを参照。
で、私のいつものパターンだと、
Sub Ken3_TAKO()
Dim n As Integer カウンター変数のｎを定義、
For n = 1 To ActiveWorkbook.Sheets.Count
Debug.Print n & "番目のシート名は" & ActiveWorkbook.Sheets(n).Name
Next n
End Sub |
ループ、１からシート数分までループ、
Sheets(n)と添え字でｎ番目のシート参照、
.Nameプロパティでシート名の表示。
オブジェクトの数を押さえて、ループでまわす。
みなさんがよくネットや上級者、ヘルプのサンプルで見かけるのはコッチ。
Sub HELP_SAMPLE()
Dim objSHEET As Object
For Each objSHEET In ActiveWorkbook.Sheets
Debug.Print "シート名は" & objSHEET.Name
Next
End Sub |
彼女へのアプローチの方法が三流君と違って、
私の方法は、女の子が何人いるか、チラッと.Countを見て横目で確認、
一番目の女の子から順に名前を聞き出す.Nameを見る。２番目に〜
For Each INのアプローチは、
ActiveWorkbook.Sheetsから一人ずつ僕の前に来てね
目の前に立った人(objSHEET)の名前は、
はい、次の人、
目の前に立った人(objSHEET)の名前は
はい、次の人、
って感じでオブジェクト変数が入れ替わっていくループかなぁ。
なんか余計、キレがなかった（笑）
感覚だけわかってくれれば、ＯＫかなぁ。
いろいろあるけど、自分にあった方法で、できればＯＫかなぁ
＊個人的には、カウンタ使ってループで書くほうが好きかなぁ。
/*
* ３．ですが、これは、マズイでしょう。。。
*/
関数作成のリクエストが来ました。
まず仕様を聞き出すか。
内容は、
渡された、Range範囲の値を１つ１つ調べ、
1000以下は背景を黄色にしてください。
ってことは、
Sub Main()
Call CHK_1000(Range("B2:F4"))
End Sub |
Sub CHK_1000(Target As Range)
判定処理
End Sub |
見たいな感じで、Rangeオブジェクトをもらって、
やり取りする関数にしますか。
さてと、事前調査で、背景を黄色は、、
ＨＥＬＰ見るのダルイからマクロ記録にするか（みなさんはマネしないでね）
Sub Macro1()
Range("B3:D6").Select
With Selection.Interior
.ColorIndex = 6
.Pattern = xlSolid
End With
Range("H9").Select
End Sub |
ここから、.ColorIndex = 6を頼りに、ヘルプを参照。
Range("B3:D6").Interior.ColorIndex = 0
Range("B3,D4,E5").Interior.ColorIndex = 6
と背景を変更可能を確認。
Sub CHK_1000(Target As Range)
Target.Interior.ColorIndex = 0 'エリアの背景をクリア
Dim n As Integer
For n = 1 To Target.Count 'ターゲットのカウント分ループ
If Target.Cells(n) < 1000 Then 'n番目の値のチェック
Target.Cells(n).Interior.ColorIndex = 6 'n番目のセルを黄色にする
End If
Next n
End Sub |
いつものパターンで、カウンタを使ってループさせて
ｎ番目のセルをチェック、１０００以下のときはｎ番目のセルを黄色に。
call CHK_1000(Range("B2:F4"))
実行するか、よしＯＫじゃん。軽い軽い。
実行結果↓、まぁ動作してますが。。。
では、パラメータを変えて、テストを続けるか。
call CHK_1000(Range("B2:B4,D2:D4,F2:F4"))
と、飛び飛びの範囲を設定してみるか。
あれ、動かないよ、Ｂ列の下を見に行ってるよ。
動作不良の実行結果↓、オイオイ、、、
実は、ここが落とし穴だったんですね。
Target.Cells(n)で参照しているのですが、
範囲をRange("B2:B4,D2:D4")みたいに指定されると動作不良をおこします。
そこで、１つ１つオブジェクトを取り出しループさせる
For Eachに変更します。
Sub CHK_1000(Target As Range)
Target.Interior.ColorIndex = 0 'エリアの背景をクリア
Dim objRANGE As Range
For Each objRANGE In Target 'オブジェクトを取り出しながらループ
If objRANGE.Value < 1000 Then '取り出したオブジェクトの値をチェック
objRANGE.Interior.ColorIndex = 6 'セルを黄色にする
End If
Next
End Sub |
と、Objectを１つ１つ取り出してチェック、色づけに変更して、
call CHK_1000(Range("B2:B4,D2:D4,F2:F4"))
を実行して、飛び飛びのセルのチェックを行う。
やっとできたかぁ（正常終了）
ふぅ〜
どっちでもイイヤって場合とFor Eachじゃないとダメなパターンがあるんだなぁ。
みなさんはハマったことありますか？
/*
* ４．おわりの挨拶
*/
今回は、
オブジェクト、コレクションのループのお話でした。
拾い読みして、
１つでも何かの参考となれば幸いです。
Ｅｘｃｅｌ／Ａｃｃｅｓｓ大好き、三流プログラマーＫｅｎ３でした。
※評価は↓で投票してね。感想は掲示板かメールでくださいね。
＜Access 列型レポートの左端に印刷したい＞
こんにちは、三流プログラマーＫｅｎ３です。
今回は、
Accessの列型のレポートに対しての小細工です。
サンプルファイルは、
http://www.ken3.org/vba/lzh/vba074.lzh
にtest074.mdb(Access97版)が保存されています。
/*
* １．今回のキッカケ
*/
掲示板 http://www.ken3.org/cgi-bin/bbs/vba/wforum.cgi に
下記の質問が書かれました。
----
> アクセスで列型のレポートを作りたいのですが、困っていることが
> あります。列型のレポートそのものは作れるのですが、ラベルがうまく
> いきません。
> 作りたいのは縦４列のデータを出力し、左端にラベルをつけるとい
> うものです。
> 詳細にラベルを置くと繰り返し出力してしまいます。結局解らなく
> て、現在はラベルと罫線と、データを分けて二重に出力するという面倒
> な方法をとっています。
> 何か解決方法はないものでしょうか？
----
やりたいことは、なんとなく、わかったけど、
さて、どうしましょう。
列型のレポート、外枠に何か書きたい、、のかぁ、、
上下はページのヘッダー、フッターがあるけど、
左右はそれらしいの無いしなぁ。今回使いたいのは左側に何か書きたいときかぁ。
少し簡単な逃げ手でもあるかやってみますか。
そんなにスゴイ手じゃないので、期待しないでくださいね。。。
/*
* ２．思いついた逃げ手の解説
*/
まずは、Accessのレポートで４列の印刷を作ります。
これは、意外と簡単かなぁ。
※サンプルは宛名ラベル印刷で作ると、楽かなぁ。
で、列の間隔を０にします。
↑参考画面
次は、左側を空けた印刷フォーマットを作成します。
普通に印刷したいコントロールを並べます。
次がポイントの前準備で、
左端に、cntAとテキストボックスのコントロールを貼り、
コントロールソース=1
集計を全体にします
↑設定したプロパティ
ホントは可視を不可視にして見えなくするけど、
テストで見えている状態でプレビューします。
↑右側無いので変だけど、連番が表示されると思います。
※こんなんで連番作れたんですね、
コントロールソース=1 と 集計全体、覚えておくと使えるかも。
さてと、確認終わったら、可視を不可視（いいえ）にして連番は見えなくします。
連番なんてカウントして、なんになるんだよ、
質問は連番を表示したいじゃないだろ。
まあまあ、あわてないでよ。
次はやっと、
左端だけに出したい文字の細工です
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
テキストボックスを
txtLEFT01など、名前を付けて作成します。
コントロールソースにIIfを使用して、細工します。
細工は、
~~~~~~~~
=IIf(([cntA] Mod 4)=1,"左端","")
と入力しました。
このＩＩｆ文で、
カウンタを４で割って余りが１、すなわち、左側の時だけ固定文字を出力してます。
実行すると、
みたいに、左端の時だけ固定の文字"左端"を表示してます。
コイツを応用して、固定の文字だけじゃなく、
=IIf(([cntA] Mod 4)=1,[ID],"")
として、左端の時だけ、IDフィールドを出すなんてこともできます。
cntAに連番が振られているので、
その連番を４で割りあまりが１の時（左端の時）
を([cntA] Mod 4)=1とＭＯＤ演算子を使って計算します。
IIfの真／偽を利用して、左端以外の偽のときは””と空白を出力、
左端のときは、固定文字でもいいし、コントロールソースでも好きに表示して、
って感じの仕組みです。
/*
* ３．仕掛けが有効な時、この仕掛けではムリな時
*/
もう、わかったと思いますが、
出力する文字が短い時は、この逃げ手でなんとかなると思います。
余白、列間の幅で吸収できる幅なら、列間を０にして、左に細工の場所を作成する。
が、
左端に印刷したい文字が長い時は、
列と列の間がかなり開いてしまうので、使えない逃げの一手です。
使えるパターン
[ZZZ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA]
[ZZZ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA]
と左端の表示が短いときは、左端の時だけ表示、あとは空白、列間代わり
使えないパターン
[ZZZZZZZ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA]
[ZZZZZZZ] [AAAAAAAAA][ ] [AAAAAAAAA][ ] [AAAAAAAAA]
と、左端の表示が長いと、列間が大きくなり使えない、、、
所詮、小細工だから、こんなもんかな。。。
連番のテクニック
と
コントロールソースでＩＩｆを使うテク
これだけでも覚えておいて下さい。
次の逃げ手を考えないと、、、、
/*
* ４．おわりの挨拶
*/
今回は、Accessレポート
・連番の振り方
・ＩＩｆをコントロールソースで使う
でした。
あっ、タイトルと内容がぜんぜん違うよ
まぁ、いつものことだからゆるしてね。。。（笑）
拾い読みして、
１つでも何かの参考となれば幸いです。
Ｅｘｃｅｌ／Ａｃｃｅｓｓ大好き、三流プログラマーＫｅｎ３でした。
※評価は↓で投票してね。感想は掲示板かメールでくださいね。
ページフッター(リンクや広告など)
[三流君(TOP ken3.org へ戻る)]
-- [VBA系TOPへ]
---- [VBA系バックナンバー目次へ移動]
------ [VBAでIEを操作 CreateObject("InternetExplorer.application")]・・・実は当店一番人気、VBAでIEを操作するサンプルです
------ [VBAでOutlookの操作 CreateObject("Outlook.Application")]・・・Outlookを使い、メール関係の処理です
------ [Access から Excel 連携 CreateObject("Excel.Application")]・・・人気のAccessからExcelへデータ書き出しなどです
------ [AccessのUserForm/サブフォームを操作]・・・アクセスでフォームを使ったサンプルです
------ [Accessのレポートを操作]・・・レポートを操作してみました
------ [Access クエリー関係やその他関数]・・・あまりまとまってませんが、スポット的な単体関数の解説です
------ [Excel UserForm(ユーザーフォーム)を操作する]・・・エクセルでユーザーフォームを作成して入力などを行ってます
------ [ExcelからAccessを操作する]・・・ExcelからAccessのマクロを起動してみました、
------ [Excel関係 関数、その他]・・・その他Excel関係です
------ [VBAでテキストファイル(*.txt,*.html,*.csv)の操作]・・・テキストファイルを使ったサンプルです
------ [VBA 標準関数関係とその他解説]・・・その他、グダグタ解説してます
広告
-- [通販系の売れ筋広告へ] ←主に楽天やAmazonのランキングです
blog
-- [三流君の作業日記] ← 日々の作業を少々
-- [通販あしあと] ← 通販ページの足跡を一覧で羅列
情報を探す
情報を探すならGoogleかな？
↓Web全体、サポート情報(support.microsoft.com)や三流君VBA(ken3.org)から検索する
書籍の購入
Webだけじゃさすがに勉強しきれないので、プログラミング関係の書籍も読んでみては？？
コンピュータ書籍の発送がハヤイ専門店
 コンピュータの本・専門店
|
※種類が豊富で探し易いです。※在庫ありが48時間以内発送が急ぎで資料や書籍がほしい時、とても助かります。
お奨め本の目次を見るだけでも勉強になったり
|
amazon.co.jpでキーワード別チェック
下記、私が設定したキーワードですが、こんな感じで資料や書籍を探ってみては？
[VBA全体を把握する] -- やはり全体をさらっと見たいですよね。
[SQL関連でＤＢ力UP] -- システムはデータベース設計が重要
[ADO接続を探る] -- VBAなのでADO接続を押さえておく
[Windows APIを探る] -- さらにAPIになて知ってれば強力だ！
[.NETを探る] -- と言っても時代は.NETに流れてるし
プログラミング以外でも知りたいことは多くって、
[人間関係] -- で、客先・上司、まわりに気を使い。
[プログラマーの自己啓発] -- プログラムだけじゃなくいろいろと向上したいよ
[コーチング・育成] -- 先輩になったら後輩(部下)の面倒をみてね。
そんなこんなでプログラマーっていろいろと大変なんだってば・・・