分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

SQL Where NOT EXISTS で集合の差(複数テーブルの差)を求める 2003年から2002年

WHERE NOT EXISTS 演算子でつなげ、複数テーブルをSelectしてみました

Select * From T_2003年売上 T2003"
 Where NOT EXISTS 
   (Select * From T_2002年売上 T2002 
     Where T2002.商品CD = T2003.商品CD 
      AND  T2002.売上金額 = T2003.売上金額)

↑2003年から2002年の同じデータを抜き取る
逆パターン：[ 基準のテーブルを逆にする test104-2.asp]もやってみてください。

商品CD	売上金額
CCCC	500

↑なんとかつながったのかな
↓テストデータ↓

商品CD	売上金額
A001	100
CCCC	500

DB内のデータを確認 DB:db100.mdb 確認用に発行したSQL:Select * From T_2003年売上商品CD 売上金額 A001 100 CCCC 500

商品CD	売上金額
A001	100
B002	50
A001	20
CCCC	1200

DB内のデータを確認 DB:db100.mdb 確認用に発行したSQL:Select * From T_2002年売上商品CD 売上金額 A001 100 B002 50 A001 20 CCCC 1200

NOT EXISTSを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp104.html]を見てください
下記、/cgi-bin/test/test104-1.aspのソース（中身）です

NOT EXISTS を使ったソースコードを紹介する

表示色の説明：ASP VBScriptは <% ～ %>
キーワードはNOT EXISTS です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>SQL Where NOT EXISTS で 集合の差(複数テーブルの差)を求める 2003年から2002年</title>
</head>
<body>
<h1>SQL Where NOT EXISTS で 集合の差(複数テーブルの差)を求める 2003年から2002年</h1>
WHERE NOT EXISTS 演算子でつなげ、複数テーブルをSelectしてみました<br>
<pre>
Select * From T_2003年売上 T2003"
 Where NOT EXISTS 
   (Select * From T_2002年売上 T2002 
     Where T2002.商品CD = T2003.商品CD 
      AND  T2002.売上金額 = T2003.売上金額)
</pre>
↑2003年から2002年の同じデータを抜き取る<br>
逆パターン：[
<a href='http://www.ken3.org/cgi-bin/test/test104-2.asp'>基準のテーブルを逆にする test104-2.asp</a>]もやってみてください。<br>
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"
  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db100.mdb")
  db.open 'データベースを開く

  '
  strSQL = "Select * From T_2003年売上 T2003"
  strSQL = strSQL & " Where NOT EXISTS "
  strSQL = strSQL & " (Select * From T_2002年売上 T2002 "
  strSQL = strSQL & "  Where T2002.商品CD = T2003.商品CD "
  strSQL = strSQL & "   AND  T2002.売上金額 = T2003.売上金額)"

  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しを(フィールド名を)そのまま書き込む
  Response.Write "<TR>"
  For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
     Response.Write "<TH>" & fld_A.Name & "</TH>"
     '↑.Nameでフィールド名を表示する
  Next
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
       Response.Write "<TD>" & fld_A.Value & "</TD>"
       '↑.Valueでフィールドの値を表示する
    Next
    Response.Write "</TR>"
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '後始末
  rs.Close '開いていたレコードセットを閉じる
  db.Close 'データベースも閉じようよ
  Set db = Nothing 'お行儀よくオブジェクトも開放しましょう

%>
<hr>
↑なんとかつながったのかな<br>
↓テストデータ↓<br>
</body>
</html>

商品:楽器関係を紹介(広告)

楽器ほか →の人気

続き(一覧)を見る

Googleで関連項目を検索する

[キーワード:NOT EXISTS] とサンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））

[Topへ戻る] －－＞[ASP系のTOPへ戻る] －－＞[記事一覧を見る]

リンク三流君ＡＳＰ系の解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[三流なプログラムコード]← 恥ずかしいのであまり載せてないけど・・・
[通販商品の足跡を紹介] ←通販商品などを紹介してます

現在時刻は、2012/02/10 3:41:23です。

SQL Where NOT EXISTS で 集合の差(複数テーブルの差)を求める 2003年から2002年