schema.ini を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはschema.ini です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>schema.ini ファイルを使って CSV 接続 フィールドの型を指定</title>
</head>
<body>
<h1>schema.ini ファイルを使って CSV 接続 フィールドの型を指定</h1>
test102-1.asp<br>
下記のテストファイルを用意して、<br>
ASPからADOを使用して.csvに接続して、単純にデータを表示してみました。<br>
※ファイル名はtest101.csvとtest102.csvで、データは,カンマで区切られてます。<br>
<pre>
日付,IP,URL,分数TEST,少数TEST,備考,予備
2004/12/25,192.168.0.1,ken3.org,1/20,1.25,備考の文字,1-2-3
2005-01-08,192.168.0.25,/asp/,1/3,5.10,日付の形式を少し変えた
2005/01/19 17:30,192.168.0.17,vba,2/7,5,時刻を付けた,04-05-06
↑ファイルの中身は同一ですが、下記の
<strong>schema.ini</strong>設定ファイルをtest102.csvでは、設定してみます
[test102.csv]
ColNameHeader=True
Format=CSVDelimited
Col1=日付 Char Width 99
Col2=IP Char Width 99
Col3=URL Char Width 99
Col4=分数TEST Char Width 99
Col5=少数TEST Char Width 99
Col6=備考 Char Width 99
Col7=予備 Char Width 99
※test102.csvでは、全てテキスト型のサイズ９９としてみました。
<b>ADOでCSVの接続</b>は、
<Font Color='Green'>'SQLのテーブル名には、ファイル名を指定します。</Font>
strSQL = "select * from test101.csv"
<Font Color='Green'>'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する</Font>
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
</pre>
こんな感じで普通に接続して、<br>
Select * from test101.csv<br>
と<br>
Select * from test102.csv<br>
でテストしてみました。
<hr>
<h2>schema.ini で設定無しのtest101.csvの結果</h2>
<% Call CSVGET_TEST("test101.csv") %>
<br>
データ型が自動的に変換されてしまい、<br>
日付に見えるデータ(04-05-06など)<br>
や<br>
小数点付きの数値に見えるデータ(192.168.0.1など)が変換されてます<br>
<hr>
<h2>schema.ini で設定有りのtest102.csvの結果</h2>
<% Call CSVGET_TEST("test102.csv") %>
↑こんな感じで、<br>
schema.iniでフィールドの型を指定すると自動に変換されなくて<br>
数値に見える文字データや日付関係で少しは使えるのかなぁ・・・<br>
<hr>
[<a Href="schema.ini" TARGET="_blank">設定ファイルschema.iniを開く</a>]<br>
[<a Href="test101.csv" TARGET="_blank">元ファイルtest101.csvを開く</a>]<br>
[<a Href="test102.csv" TARGET="_blank">元ファイルtest102.csvを開く</a>]<br>
<br>
参考URL:
[<a Href="http://support.microsoft.com/default.aspx?scid=kb;ja;155512&Product=accJPN" TARGET="_blank">[AC97]VBAから Schema.ini ファイルを作成する方法</a>]<br>
<hr>
<%
Sub CSVGET_TEST(strFileName)
'ADO DB Recordset オブジェクトを作成する、英文そのままじゃん
Set rs=Server.CreateObject("ADODB.Recordset")
'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
'SQLのテーブル名には、ファイル名を指定します。
strSQL = "select * from " & strFileName '受け取ったファイル名を追加する
Response.Write "使用する接続文字列は<br>"
Response.Write "<STRONG><CODE>" & Con & "</CODE></STRONG><br>"
Response.Write "発行するSQL文字列は<br>"
Response.Write "<STRONG><CODE>" & strSQL & "</CODE></STRONG><br>"
'接続文字列、SQLを渡して、レコードセットを開く
rs.Open strSQL, Con, 0 '0=adOpenForwardOnly
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しを(フィールド名を)そのまま書き込む
Response.Write "<TR>"
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TH>" & fld_A.Name & "</TH>" '←.Nameでフィールド名
Next
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TD>" & fld_A.Value & "</TD>" '←.Valueでフィールドの値
Next
Response.Write "</TR>"
rs.MoveNext '次のレコードに移動する
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
'後始末
rs.Close '開いていたレコードセットを閉じる
Set rs = Nothing 'お行儀よくオブジェクトも開放しましょう
End Sub
%>
</body>
</html>
| 最近発売の雑誌を紹介する
今週発売の男性誌です。プログラミング以外にも興味を持って？？？
- カジカジ 2008年 06月号
- BEST CLUB (ベストクラブ) 2008年 06月号
- SpyMaster (スパイマスター) 東海版 2008年 06月号
- KING (キング) 2008年 06月号
- men's egg (メンズエッグ) 2008年 06月号
- Ollie (オーリー) 2008年 06月号
- BRUTUS (ブルータス) 2008年 6/1号
- Pen (ペン) 2008年 6/1号
- おとなの週末 2008年 06月号
|