Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ= を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはDriver={Microsoft Text Driver (*.txt; *.csv)};DBQ= です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>ADO CSV 接続 フィールドの型についてテストしてみた</title>
</head>
<body>
<h1>ADO CSV 接続 フィールドの型についてテストしてみた</h1>
test101-1.asp<br>
下記のテストデータを用意して、<br>
ASPからADOを使用して.csvに接続して、単純にデータを表示してみました。<br>
※ファイル名はtest101.csvで、データは,カンマで区切られてます。<br>
<pre>
日付,IP,URL,分数TEST,少数TEST,備考,予備
2004/12/25,192.168.0.1,ken3.org,1/20,1.25,備考の文字,1-2-3
2005-01-08,192.168.0.25,/asp/,1/3,5.10,日付の形式を少し変えた
2005/01/19 17:30,192.168.0.17,vba,2/7,5,時刻を付けた,04-05-06
まだまだ、テストデータとして、足りないけど、↑手抜きでこんな感じ。
※カンマと小数点が見難いが・・・
<b>ADOでCSVの接続</b>は、
<Font Color='Green'>'SQLのテーブル名には、ファイル名を指定します。</Font>
strSQL = "select * from test101.csv"
<Font Color='Green'>'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する</Font>
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
</pre>
こんな感じで普通に接続してみました。
<hr>
<%
'ADO DB Recordset オブジェクトを作成する、英文そのままじゃん
Set rs=Server.CreateObject("ADODB.Recordset")
'SQLのテーブル名には、ファイル名を指定します。
strSQL = "select * from test101.csv"
'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
Response.Write "使用する接続文字列は<br>"
Response.Write "<STRONG><CODE>" & Con & "</CODE></STRONG><br>"
Response.Write "発行するSQL文字列は<br>"
Response.Write "<STRONG><CODE>" & strSQL & "</CODE></STRONG><hr>"
'接続文字列、SQLを渡して、レコードセットを開く
rs.Open strSQL, Con, 0 '0=adOpenForwardOnly
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しを(フィールド名を)そのまま書き込む
Response.Write "<TR>"
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TH>" & fld_A.Name & "</TH>" '←.Nameでフィールド名
Next
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TD>" & fld_A.Value & "</TD>" '←.Valueでフィールドの値
Next
Response.Write "</TR>"
rs.MoveNext '次のレコードに移動する
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
'後始末
rs.Close '開いていたレコードセットを閉じる
Set rs = Nothing 'お行儀よくオブジェクトも開放しましょう
%>
<hr>
[<a Href="test101.csv" TARGET="_blank">元ファイルtest101.csvを開く</a>]<br>
</body>
</html>
| 最近発売の雑誌を紹介する
プログラマーは漫画好き？仕事のじゃまにならない程度に・・・読んでみては？
- 少年ガンガン 2008年 06月号
- つりコミック 2008年 06月号
- 月刊 まんがライフオリジナル 2008年 06月号
- コミックビーム 2008年 06月号
- COMIC B's-LOG (コミックビーズログ) 2008年 06月号
- まんがタイムラブリー 2008年 06月号
- Mystery Sara (ミステリー・サラ) 2008年 06月号
- COMIC 乱 TWINS (ツウィンズ) 2008年 06月号
- 別冊 フレンド 2008年 06月号
|