Classic ASP のテストページです。 情報が古いので参考程度に読んだりテストしてみてください。
三流君(TOP) /ASPで遊ぶ /ASP記事一覧を見る
分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

SQL UNIONでつなげ複数テーブルを読み込む

UNION 演算子でつなげ、複数テーブルをSelectしてみました
Select * From T_2002年売上
 UNION
  Select * From T_2003年売上
   UNION
    Select * From T_2004年売上
やっと縦に並んで取り出すことができたのかな？
商品CD売上金額
A00120
A001100
B00250
B002250
CCCC500
CCCC1200
DDDDD5000
↑よく見ると、A001 金額100のデータが2002年と2003年にあるのに１つしか・・・
↓テストデータ↓
DB内のデータを確認
DB:db100.mdb
確認用に発行したSQL:Select * From T_2002年売上
商品CD売上金額
A001100
B00250
A00120
CCCC1200
DB内のデータを確認
DB:db100.mdb
確認用に発行したSQL:Select * From T_2003年売上
商品CD売上金額
A001100
CCCC500
DB内のデータを確認
DB:db100.mdb
確認用に発行したSQL:Select * From T_2004年売上
商品CD売上金額
B002250
DDDDD5000

UNIONを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp100.html]を見てください
下記、/cgi-bin/test/test100-2.aspのソース（中身）です

UNION を 使った ソースコードを紹介する

表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはUNION です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>SQL UNIONでつなげ複数テーブルを読み込む</title>
</head>
<body>
<h1>SQL UNIONでつなげ複数テーブルを読み込む</h1>
UNION 演算子でつなげ、複数テーブルをSelectしてみました<br>
<pre>
Select * From T_2002年売上
 UNION
  Select * From T_2003年売上
   UNION
    Select * From T_2004年売上
</pre>
やっと縦に並んで取り出すことができたのかな？<br>
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"
  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db100.mdb")
  db.open 'データベースを開く

  'UNION で ３つのテーブルをつなげる
  strSQL = "Select * From T_2002年売上"
  strSQL = strSQL & " UNION "
  strSQL = strSQL & " Select * From T_2003年売上"
  strSQL = strSQL & " UNION "
  strSQL = strSQL & " Select * From T_2004年売上"

  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しを(フィールド名を)そのまま書き込む
  Response.Write "<TR>"
  For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
     Response.Write "<TH>" & fld_A.Name & "</TH>"
     '↑.Nameでフィールド名を表示する
  Next
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
       Response.Write "<TD>" & fld_A.Value & "</TD>"
       '↑.Valueでフィールドの値を表示する
    Next
    Response.Write "</TR>"
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '後始末
  rs.Close '開いていたレコードセットを閉じる
  db.Close 'データベースも閉じようよ
  Set db = Nothing 'お行儀よくオブジェクトも開放しましょう

%>
<hr>
↑よく見ると、A001 金額100のデータが2002年と2003年にあるのに１つしか・・・<br>
↓テストデータ↓<br>
</body>
</html>


Googleで関連項目を検索する

[キーワード:UNION] と サンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。
Google

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））
[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

リンク 三流君 ＡＳＰ系 の 解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力 で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[永遠の下書き日記？]← 恥ずかしいのであまり載せてないけど・・・
[ひとりで掲示板？] ←一人で？掲示板？ぉぃぉぃ

[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

現在時刻は、2019/11/22 0:17:18です。