Request.Form(xxx).Count を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはRequest.Form(xxx).Count です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>ASP FORM リストボックスの複数選択 VALUE=を個別に作成(Request.Form(xxx).Countで複数チェック)</title>
</head>
<body>
<h1>ASP FORM リストボックスの複数選択 VALUE=を個別に作成(Request.Form(xxx).Countで複数チェック)</h1>
<font color="blue">FORM リストボックスの複数選択(selectタグ multiple で VALUE=を個別に作成)</font><br>
<FORM ACTION="test093-5.asp" METHOD="POST">
表示したい・区分を選択後、検索ボタンを押してください<br>
Ctrlキーを押しながらクリックすると、複数を選ぶことができます<br>
<SELECT NAME="KUBUN" SIZE="5" multiple>
<option VALUE="ASP">ASP 感想(ASP)</option>
<option VALUE="VBA">VBA 感想(VBA)</option>
<option VALUE="24H">コンビニ系(24H)</option>
<option VALUE="GUCHI">愚痴系(GUCHI)</option>
</SELECT><br>
<INPUT TYPE="submit" VALUE="検索する">
</FORM>
<%
'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
Set db=Server.CreateObject("ADODB.Connection")
'データアクセスにはJet.OLEDB.4.0を使うことを設定
db.Provider = "Microsoft.Jet.OLEDB.4.0"
'次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
db.ConnectionString = Server.MapPath("db029.mdb")
'やっとデータベースを開ける
db.open
'WHERE句を作成する
If Request.Form("KUBUN").Count > 0 Then '項目数をチェック
'複数の時、1番目（最初の条件をまず代入）
strWHERE = " Where F_KUBUN = '" & Request.Form("KUBUN")(1) & "' "
'次の条件((2)から)をループで追加する
For n = 2 To Request.Form("KUBUN").Count
'Orで条件をつなげる
strWHERE = strWHERE & " Or F_KUBUN = '" & Request.Form("KUBUN")(n) & "' "
Next
Else
strWHERE = "" 'データ無しの時は条件をカラにする
End If
'SQL文を作成する (作成したWHERE句を組み合わせる)
strSQL = "Select * From KANSOU " '感想(KANSOU)テーブルから全項目(*)
strSQL = strSQL & strWHERE
strSQL = strSQL & " ORDER BY WriteTime DESC" '並べ替えは時間の降順
'オマケで画面にデータ表示
Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'お約束のレコードセットの作成 SQL文の発行
Set rs = db.Execute(strSQL)
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しをバカっぽく、そのまま書き込む
Response.Write "<TR>"
Response.Write "<TD>日付</TD>"
Response.Write "<TD>区分</TD>"
Response.Write "<TD>メモ</TD>"
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する、行開始のタグ＜ＴＲ＞
'データの中身を表示
Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
Response.Write "</TR>"
'次のレコードにポインタを移動する
rs.MoveNext 'これを忘れると悲惨なことに、、、
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
rs.Close '開いていたレコードセットを閉じる
db.Close 'データベースも閉じようよ
Set db = Nothing 'お行儀よくオブジェクトも開放しましょう
%>
<HR>
終了です。<br>
受け取った項目名をArrayで文字列配列を作成して、<br>
ループで回し、WHERE句を作成してみました<br>
<A href="test029-1.asp">データの登録（テストデータを増やす）</a><br>
</body>
</html>
|