分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

FORM CHECKBOX VALUE=を個別に作成(Replaceで途中の,を置換 WHERE IN句を使用する)

発行する（した）ＳＱＬ文は
Select * From KANSOU ORDER BY WriteTime DESC
です

日付	区分	メモ
2012/02/10 4:00:02	GUCHI	TEST DATA 1 xxx
2012/02/10 2:30:58	GUCHI	TEST DATA 14 xxx
2012/02/10 1:19:45	GUCHI	TEST DATA 8 xxx
2012/02/09 10:32:57	VBA	TEST DATA 71
2012/02/07 2:30:41	24H	TEST DATA 45 xxx
2012/02/05 1:20:40	VBA	TEST DATA 94 xxx
2012/02/04 4:02:44	ASP	TEST DATA 45 xxx
2012/02/02 23:33:42	24H	水のいらないヘアケア
2012/02/02 23:33:17	GUCHI	水・ミネラルウォーター
2012/02/02 23:32:51	VBA	紙おむつ
2012/02/02 23:32:26	ASP	家具転倒防止グッズ
2012/02/02 16:15:34	ASP	TEST DATA 24
2012/02/02 13:02:35	ASP	123456
2012/02/02 1:23:46	GUCHI	TEST DATA 0 xxx
2012/01/24 23:15:24	ASP	TEST DATA 48
2012/01/24 18:57:10	GUCHI	ボディ・フェイシャルシート
2012/01/24 18:56:20	ASP	スポーツドリンク
2012/01/23 16:20:28	ASP	00
2012/01/20 11:41:06	VBA	TEST DATA 54
2012/01/19 16:48:40	VBA	TEST DATA 62
2012/01/16 1:20:07	ASP	TEST DATA 12 xxx
2012/01/12 17:21:05	ASP	TEST DATA 96
2012/01/09 10:45:44	24H	ノートパソコン
2012/01/09 10:45:18	GUCHI	ダウン
2012/01/09 10:44:53	VBA	ウォータータンク

終了です。
チェックボックスの項目名をArrayで文字列配列を作成して、
ループで回し、WHERE句を作成してみました(少しは進化した？)
データの登録（テストデータを増やす）

CHECKBOX VALUEを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp093.html]を見てください
下記、/cgi-bin/test/test093-3.aspのソース（中身）です

CHECKBOX VALUE を使ったソースコードを紹介する

表示色の説明：ASP VBScriptは <% ～ %>
キーワードはCHECKBOX VALUE です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>FORM CHECKBOX VALUE=を個別に作成(Replaceで途中の,を置換 WHERE IN句を使用する)</title>
</head>
<body>
<h1>FORM CHECKBOX VALUE=を個別に作成(Replaceで途中の,を置換 WHERE IN句を使用する)</h1>
<FORM ACTION="test093-3.asp" METHOD="POST">
<font color="blue">FORM CHECKBOX VALUE=を個別に作成 Where句を作成するTEST</font><br>
表示したい・区分をチェックしてから検索ボタンを押してください<br>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="ASP">ASP<br>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="VBA">VBA<br>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="24H">コンビニ系<br>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="GUCHI">愚痴系<br>
<INPUT TYPE="submit" VALUE="検索する">
</FORM>

<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db029.mdb")

  'やっとデータベースを開ける
  db.open

  'WHERE句を作成する
  strKUBUN = Request.Form("KUBUN") 'フォームから区分を受け取る
  If strKUBUN = "" Then '区分が選択されていなかったら
    strWHERE = ""   'データ無しの時は条件をカラにする
  Else  ',を変換してWHERE句を作成する
    ' ASP, 24Hの文字を", "(カンマとスペース１つ)を','に変換する
    strWORK = Replace(strKUBUN, ", ", "','")  '置き換える
    strWHERE = " Where F_KUBUN IN ('" & strWORK & "') "
  End If

  'SQL文を作成する (作成したWHERE句を組み合わせる)
  strSQL = "Select * From KANSOU "  '感想(KANSOU)テーブルから全項目(*)
  strSQL = strSQL & strWHERE
  strSQL = strSQL & " ORDER BY WriteTime DESC" '並べ替えは時間の降順

  'オマケで画面にデータ表示
  Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
  Response.Write strSQL & "</font></B><br>です<hr>"

  'お約束のレコードセットの作成 SQL文の発行
  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しをバカっぽく、そのまま書き込む
  Response.Write "<TR>"
  Response.Write "<TD>日付</TD>"
  Response.Write "<TD>区分</TD>"
  Response.Write "<TD>メモ</TD>"
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する、行開始のタグ＜ＴＲ＞
    'データの中身を表示
    Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
    Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
    Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
    Response.Write "</TR>"
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  rs.Close         '開いていたレコードセットを閉じる
  db.Close         'データベースも閉じようよ
  Set db = Nothing 'お行儀よくオブジェクトも開放しましょう

%>

<HR>
終了です。<br>
チェックボックスの項目名をArrayで文字列配列を作成して、<br>
ループで回し、WHERE句を作成してみました(少しは進化した？)<br>
<A href="test029-1.asp">データの登録（テストデータを増やす）</a><br>
</body>
</html>

商品:家電関係を紹介(広告)

家電ほか →の人気

続き(一覧)を見る

Googleで関連項目を検索する

[キーワード:CHECKBOX VALUE] とサンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））

[Topへ戻る] －－＞[ASP系のTOPへ戻る] －－＞[記事一覧を見る]

リンク三流君ＡＳＰ系の解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[三流なプログラムコード]← 恥ずかしいのであまり載せてないけど・・・
[通販商品の足跡を紹介] ←通販商品などを紹介してます

現在時刻は、2012/02/10 4:13:43です。