Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ= を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはDriver={Microsoft Text Driver (*.txt; *.csv)};DBQ= です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>ADOでCSVファイルと接続、発売日順にソートしてみた</title>
</head>
<body>
<h1>ADOでCSVファイルと接続、発売日順にソートしてみた</h1>
test080-2.asp<br>
ASPからADOを使用してテキストファイル(*.csv)に接続を行い、ソートしてみた<br>
ファイル名はtest080.csvで、データは,カンマで区切られてます。<br>
<pre>
<Font Color='Green'>'SQLのテーブル名には、ファイル名を指定します。</Font>
strSQL = "select * from test080.csv Order By 発売日 DESC"
<Font Color='Green'>'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する</Font>
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
</pre><br>
こんな感じで作成してみました。（詳細は下のほうにあるソースを見てください）
<hr>
<%
'ADO DB Recordset オブジェクトを作成する、英文そのままじゃん
Set rs=Server.CreateObject("ADODB.Recordset")
'SQLのテーブル名には、ファイル名を指定します。
'Order By 発売日 DESCで、発売日の降順にしてみました
strSQL = "select * from test080.csv Order By 発売日 DESC"
'接続情報の作成 ドライバーの指定と、DBQには、パスのみを指定する
Con = "Driver={Microsoft Text Driver (*.txt; *.csv)};DBQ=" & _
Server.MapPath(".") & ";"
'↑MapPathに(".")を渡し、カレントディレクトリを渡す
Response.Write "使用する接続文字列は<br>"
Response.Write "<STRONG><CODE>" & Con & "</CODE></STRONG><br>"
Response.Write "発行するSQL文字列は<br>"
Response.Write "<STRONG><CODE>" & strSQL & "</CODE></STRONG><hr>"
'接続文字列、SQLを渡して、レコードセットを開く
rs.Open strSQL, Con, 0 '0=adOpenForwardOnly
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しを(フィールド名を)そのまま書き込む
Response.Write "<TR>"
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TH>" & fld_A.Name & "</TH>" '←.Nameでフィールド名
Next
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する
For Each fld_A In rs.Fields 'フィールドのアイテムに対してループ
Response.Write "<TD>" & fld_A.Value & "</TD>" '←.Valueでフィールドの値
Next
Response.Write "</TR>"
rs.MoveNext '次のレコードに移動する
Loop
Response.Write "</TABLE></SAMP>" 'テーブルは終わりです
'後始末
rs.Close '開いていたレコードセットを閉じる
Set rs = Nothing 'お行儀よくオブジェクトも開放しましょう
%>
<hr>
[<a Href="test080.csv" TARGET="_blank">元ファイルtest080.csvを開く</a>]<br>
</body>
</html>
| 最近発売の雑誌を紹介する
科学や技術の雑誌です。
- 農業と経済 2008年 06月号
- 省エネルギー 2008年 05月号
- 設備と管理 2008年 06月号
- 電気計算 2008年 06月号
- 電気店 2008年 06月号
- 電気評論 2008年 05月号
- 電気と工事 2008年 06月号
- 電設技術 2008年 05月号
- 固体物理 2008年 04月号
|