Classic ASP のテストページです。 情報が古いので参考程度に読んだりテストしてみてください。
三流君(TOP) /ASPで遊ぶ /ASP記事一覧を見る
分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

上期計（売上4〜9）を計算して表示する

Select T_月別売上.商品CD, T_商品.商品名,
 売上4,売上5,売上6,売上7,売上8,売上9,
 ([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計
  From T_月別売上, T_商品
   Where T_月別売上.商品CD = T_商品.商品CD
UNION ALL
Select Left([T_月別売上.商品CD], 1) & 'ZZZZ' AS GroupCD
 , '小計' AS Dummy商品名
 , Sum([売上4]) , Sum([売上5]) , Sum([売上6])
 , Sum([売上7]) , Sum([売上8]) , Sum([売上9])
 , Sum([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計
  From T_月別売上, T_商品
   Where T_月別売上.商品CD = T_商品.商品CD
    Group By Left([T_月別売上.商品CD], 1) & 'ZZZZ'
Order By T_月別売上.商品CD
と、SQL文を作成してみた。
商品CD商品名売上4売上5売上6売上7売上8売上9上期計
A1コーラ12345621
A2オレンジ20456724
A3りんご0000000
AZZZZ小計3279111345
B1スーパードライ426781037
B2モルツ0000000
B3黒ラベル6489101249
BZZZZ小計1061416182286
D1コート0000000
D2マフラー0000000
DZZZZ小計0000000
終了です。
DB内のデータを確認
DB:db072.mdb
確認用に発行したSQL:Select * From T_月別売上
商品CD売上4売上5売上6売上7売上8売上9売上10売上11売上12売上1売上2売上3
A1123456000000
A2204567000000
A30000002030201025
B14267810000000
B2000000123456
B364891012000000
C1111111000000
C2222222000000
D100000021010520
D2000000146310
DB内のデータを確認
DB:db072.mdb
確認用に発行したSQL:Select * From T_商品
商品CD商品名
A1コーラ
A2オレンジ
A3りんご
B1スーパードライ
B2モルツ
B3黒ラベル
D1コート
D2マフラー

UNION ALLを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp076.html]を見てください
下記、/cgi-bin/test/test076-2.aspのソース（中身）です

UNION ALL を 使った ソースコードを紹介する

表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはUNION ALL です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>上期計（売上4〜9）を計算して表示する</title>
</head>
<body>
<h1>上期計（売上4〜9）を計算して表示する</h1>
<pre>
Select T_月別売上.商品CD, T_商品.商品名,
 売上4,売上5,売上6,売上7,売上8,売上9,
 ([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計
  From T_月別売上, T_商品
   Where T_月別売上.商品CD = T_商品.商品CD
<b>UNION ALL</b>
Select Left([T_月別売上.商品CD], 1) & 'ZZZZ' AS GroupCD
 , '小計' AS Dummy商品名
 , Sum([売上4]) , Sum([売上5]) , Sum([売上6])
 , Sum([売上7]) , Sum([売上8]) , Sum([売上9])
 , Sum([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計
  From T_月別売上, T_商品
   Where T_月別売上.商品CD = T_商品.商品CD
    Group By Left([T_月別売上.商品CD], 1) & 'ZZZZ'
Order By T_月別売上.商品CD
</pre>
と、SQL文を作成してみた。
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"
  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("db072.mdb")
  db.open 'データベースを開く

  'T_月別売上 から 商品コード、売上４〜９を取得する
  strSQL = "Select T_月別売上.商品CD, T_商品.商品名,"
  strSQL = strSQL & " 売上4,売上5,売上6,売上7,売上8,売上9,"
  strSQL = strSQL & "([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計"
  strSQL = strSQL & " From T_月別売上, T_商品 "
  strSQL = strSQL & " Where T_月別売上.商品CD = T_商品.商品CD "

  'UNION ALL演算子をはさむ。
  strSQL = strSQL & " UNION ALL"

  'Sum集計関数で項目の合計を計算する
  strSQL = strSQL & " Select Left([T_月別売上.商品CD], 1) & 'ZZZZ' AS GroupCD "
  strSQL = strSQL & ", '小計' AS Dummy商品名 "
  strSQL = strSQL & ", Sum([売上4]) , Sum([売上5]) , Sum([売上6])"
  strSQL = strSQL & ", Sum([売上7]) , Sum([売上8]) , Sum([売上9])"
  strSQL = strSQL & ", Sum([売上4]+[売上5]+[売上6]+[売上7]+[売上8]+[売上9]) AS 上期計"
  strSQL = strSQL & " From T_月別売上, T_商品 "
  strSQL = strSQL & " Where T_月別売上.商品CD = T_商品.商品CD "
  strSQL = strSQL & " Group By Left([T_月別売上.商品CD], 1) & 'ZZZZ'"

  'Order By 商品CD と商品コードで並べ替える
  strSQL = strSQL & " Order By T_月別売上.商品CD"

  Set rs = db.Execute(strSQL) 'SQL発行、レコードセットの作成

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しを(フィールド名を)そのまま書き込む
  Response.Write "<TR>"
  For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
     Response.Write "<TH>" & fld_A.Name & "</TH>"
     '↑.Nameでフィールド名を表示する
  Next
  Response.Write "</TR>"

  'お約束のＥＯＦまでループは(データが無くなるまでループ)、
  Do While rs.EOF = False   'レコードセットの.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    For Each fld_A In Rs.Fields 'フィールドのアイテムに対してループ
       Response.Write "<TD>" & fld_A.Value & "</TD>"
       '↑.Valueでフィールドの値を表示する
    Next
    Response.Write "</TR>"
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '後始末
  rs.Close '開いていたレコードセットを閉じる
  db.Close 'データベースも閉じようよ
  Set db = Nothing 'お行儀よくオブジェクトも開放しましょう

%>
<hr>
終了です。<br>
</body>
</html>


Googleで関連項目を検索する

[キーワード:UNION ALL] と サンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。
Google

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））
[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

リンク 三流君 ＡＳＰ系 の 解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力 で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[永遠の下書き日記？]← 恥ずかしいのであまり載せてないけど・・・
[ひとりで掲示板？] ←一人で？掲示板？ぉぃぉぃ

[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

現在時刻は、2019/02/16 19:31:31です。