FileSystemObjectの.GetTempName(一時ファイル名を作成する)

分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

一時ファイル名を作成する
FileSystemObjectの.GetTempName

FileSystemObjectの.GetTempNameを使用して、一時ファイル名を取得してみます

.GetTempNameを使用すると、一時ファイルの名称を作成してくれます。
あとは、その名称を使用して、ファイルを作成します
(自動的にファイルは作られないので注意してください)
※下記の実行結果とソースを見てください。

.GetTempNameで作成した名称[rad1A87C.tmp]
d:\users\ken3_org\Cgi-bin\test\work\rad1A87C.tmpを作成

d:\users\ken3_org\Cgi-bin\test\workのファイル一覧です
index.html 2003/07/22 10:54:04
rad1A87C.tmp 2012/02/10 1:56:21
rad20FCF.tmp 2012/02/09 23:02:46

再度テンポラリファイルを作成する
テストのテンポラリファイルを削除する

.GetTempNameを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp069.html]を見てください
下記、/cgi-bin/test/test069-1.aspのソース（中身）です

.GetTempName を使ったソースコードを紹介する

表示色の説明：ASP VBScriptは <% ～ %>
キーワードは.GetTempName です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>FileSystemObjectの.GetTempName(一時ファイル名を作成する)</title>
</head>
<body>
<h2>一時ファイル名を作成する<br>FileSystemObjectの.GetTempName</h2>
<b>FileSystemObjectの.GetTempName</b>を使用して、一時ファイル名を取得してみます<br>
<br>
.GetTempNameを使用すると、一時ファイルの名称を作成してくれます。<br>
あとは、その名称を使用して、ファイルを作成します<br>
(自動的にファイルは作られないので注意してください)<br>
※下記の実行結果とソースを見てください。<br>
<hr>
<%
  '*1 FileSystemObjectを生成します、、って英文、そのままジャン。
  Set objFS = Server.CreateObject("Scripting.FileSystemObject")

  '*2 .GetTempNameを使用して、一時ファイル名を作成する
  strTEMPNAME = objFS.GetTempName  '.GetTempNameを使用してリターン値をもらう
  Response.Write ".GetTempNameで作成した名称[<b>" & strTEMPNAME & "</b>]<br>"

  '現在のフォルダーから相対位置のworkディレクトリの名称を取り出す
  strFDIRNAME = Server.MapPath("work/") 'フォルダー名取得

  'work/xxxxのファイルを作成して、テストデータを書き込む
  Response.Write strFDIRNAME & "\" & strTEMPNAME & "を作成<br><br>"
  Set objTEXTFILE = objFS.CreateTextFile(strFDIRNAME & "\" & strTEMPNAME)
  objTEXTFILE.WriteLine "現在時刻は" & Now()
  objTEXTFILE.WriteLine "テンポラリファイルのテストでした(笑)"
  objTEXTFILE.Close
  Set objTEXTFILE = Nothing

  '確認でファイルリストの表示.GetFolderで取得後、一覧表示
  Response.Write strFDIRNAME & "のファイル一覧です<br>" & vbCRLF
  Set objDIR = objFS.GetFolder(strFDIRNAME)

  '.Filesコレクションにアクセスする
  For Each objFILE In objDIR.Files
    strFNAME = objFILE.Name  '取り出したobjFILEの.Nameを取得
    If strFNAME = strTEMPNAME Then Response.Write "<b>"
    Response.Write "<a href='work/" & strFNAME & "'>"
    Response.Write strFNAME & "</a>" & vbTab
    'おまけで更新日の表示
    Response.Write objFILE.DateLastModified & "<br>" & vbCRLF
    If strFNAME = strTEMPNAME Then Response.Write "</b>"
  Next

%>
<hr>
<a href="test069-1.asp"><b>再度</b>テンポラリファイルを<b>作成</b>する</a><br>

<a href="test071-1.asp">テストのテンポラリファイルを<b>削除する</b></a><br>
<br>
</body>
</html>

商品:服と靴関係を紹介(広告)

服と靴など →の人気

続き(一覧)を見る

Googleで関連項目を検索する

[キーワード:.GetTempName] とサンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））

[Topへ戻る] －－＞[ASP系のTOPへ戻る] －－＞[記事一覧を見る]

リンク三流君ＡＳＰ系の解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[三流なプログラムコード]← 恥ずかしいのであまり載せてないけど・・・
[通販商品の足跡を紹介] ←通販商品などを紹介してます

現在時刻は、2012/02/10 1:56:21です。

一時ファイル名を作成するFileSystemObjectの.GetTempName