Session を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはSession です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>セッション変数 Session("USERNAME") で名前の管理</title>
</head>
<body>
<h2>セッション変数 Session("USERNAME") で名前の管理</h2>
<h3>じゃんけんゲーム</h3><br>
<%
'ユーザー名が送られていたら、セッション変数にセットする
D = Request.QueryString("UNAME") 'データを代入
If Len(D) <> 0 Then 'データあり
Session("USERNAME") = D '名前の代入
End If
'パラメータをチェックする、セッション変数に名前が入っているか？
USER_NAME = Session("USERNAME")
'Lenで変数の長さをチェックする
If Len(Trim(USER_NAME)) = 0 Then '名前が未入力なら
Call INPUT_NAME() '名前入力フォームの表示
Else
D = Request.QueryString("DATA") 'データを代入(選択された手)
If Len(D) = 1 Then 'データあり
Call HANTEI(D) '判断用の関数を呼ぶ
End If
Call INPUT_FORM() '入力用のフォームを表示する、再度入力させる
End If
%>
<hr>
アナタのIP Address=<%=Request.ServerVariables("REMOTE_ADDR")%><br>
Session.SessionID=<%=Session.SessionID%><br>
サーバー再起動時に同じセッションIDが振られることがあるが、<br>
通常は毎回違う値が表示される<br>
ブラウザを閉じてからまた開いたり<br>
隣のインターネット上同じＩＰの端末から２つ同時に開いたり
してテストしてみよう<br><hr>
</body>
</html>
<% '名前入力フォームの表示
Sub INPUT_NAME()
Response.Write "<HR>"
Response.Write "<FORM ACTION='test064-1.asp' METHOD='GET'>"
Response.Write "あなたのお名前は？<br>"
Response.Write "<INPUT TYPE='text' NAME='UNAME'><br>"
Response.Write "<INPUT TYPE='submit' VALUE='名前の登録'><br>"
Response.Write "</FORM>"
End Sub
%>
<% '入力フォームの表示(勝負する手を入力)
Sub INPUT_FORM()
Response.Write "<HR>"
Response.Write "<FORM ACTION='test064-1.asp' METHOD='GET'>"
Response.Write "<b>" & USER_NAME & "</b>さん、あなたの手は？<br>"
Response.Write "<INPUT TYPE='RADIO' NAME='DATA' VALUE='1'>１．グー<br>"
Response.Write "<INPUT TYPE='RADIO' NAME='DATA' VALUE='2'>２．チョキ<br>"
Response.Write "<INPUT TYPE='RADIO' NAME='DATA' VALUE='3'>３．パー<br>"
Response.Write "<INPUT TYPE='submit' VALUE='勝負する'><br>"
Response.Write "</FORM>"
End Sub
%>
<% '乱数を発生させて勝負する
Sub HANTEI(strNO) 'ユーザーの手を受取り判断する
Dim nCON 'コンピュータの手１〜３の数値が入る
Dim nPC 'ユーザーさんの手
Dim strTE(3) '(*1)配列変数を宣言
strTE(1) = "グー" '(*2)配列にメッセージを代入
strTE(2) = "チョキ"
strTE(3) = "パー"
'入力値の判断、エラーならメッセージを表示させ抜ける
'If文で1,2,3以外を判断する
If strNO <> "1" And strNO <> "2" And strNO <> "3" Then
Response.Write "[" & strNO & "]は不正な入力です"
Exit Sub '<--Exit Subを使用してここでプログラムを抜ける
End If
'コンピュータの手を決定
Randomize ' 乱数発生ルーチンを初期化します。
nCON = Int((3 * Rnd) + 1) '1 から 3 までの乱数を発生させます。
'結果判断と表示
'ユーザーの手を表示する
nPC = CInt(strNO) 'CInt関数で数値型に変換する
Response.Write USER_NAME & "さんの手は、"
Response.Write strTE(nPC) & "です<br>" '(*3)ここでnPC番目を表示
'(*4)同様にコンピュータの手を表示する
Response.Write "コンピュータの手は" & strTE(nCON) & "です<br>"
'結果の判断
'まず、引き分けを判断
If nPC = nCON Then Response.Write "引き分けです<br>"
'次に自分が勝ちの手を判断 グーvsチョキ,チョキvsパー,パーvsグー
If nPC = 1 And nCON = 2 Then Response.Write "アナタの勝ちです<br>"
If nPC = 2 And nCON = 3 Then Response.Write "アナタの勝ちです<br>"
If nPC = 3 And nCON = 1 Then Response.Write "アナタの勝ちです<br>"
'コンピュータが勝ちか判断 グーvsパー，チョキvsグー,バーvsチョキ
If nPC = 1 And nCON = 3 Then Response.Write "私（コンピュータ）の勝ちです<br>"
If nPC = 2 And nCON = 1 Then Response.Write "私（コンピュータ）の勝ちです<br>"
If nPC = 3 And nCON = 2 Then Response.Write "私（コンピュータ）の勝ちです<br>"
End Sub
%>
| 最近発売の雑誌を紹介する
スポーツ系の雑誌です。プログラマーさん運動不足になってませんか？
- BOWLING magazine (ボウリング・マガジン) 2008年 06月号
- IRONMAN (アイアンマン) 2008年 06月号
- Urawa Reds Magazine (浦和レッズマガジン) 2008年 06月号
- CALCiO (カルチョ) 2002 2008年 07月号
- WORLD SOCCER GRAPHIC (ワールドサッカーグラフィック) 2008年 06月号
- 月刊 GRUN (グラン) 2008年 06月号
- Regina (レジーナ) 初夏号 2008年5/27号
- 陸上競技マガジン 2008年 06月号
- 月刊 秘伝 2008年 06月号
|