Split を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはSplit です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>SQL WHERE句 複数条件作成で SplitとUBoundを使用</title>
</head>
<body>
<h1>SQL WHERE句 複数条件作成で SplitとUBoundを使用</h1>
test046-2.asp<br>
<hr>
Request.QueryString("KUBUN")=<%=Request.QueryString("KUBUN")%><br>
<% '頭で、入力パラメーターをチェックする
strWHERE = "Where " '初期値の代入
strBOX = Split(Request.QueryString("KUBUN"), ",") 'カンマで区切る
Response.Write "UBound(strBOX)=" & UBound(strBOX) & "<br>"
'ループでデータを作成する
For i = 0 To UBound(strBOX) 'UBound使用インデックス最大値までループ
Response.Write "strBOX(" & i & ")=" & strBOX(i) & "<br>"
If strWHERE <> "Where " Then strWHERE = strWHERE & " OR " '２個目〜
strWHERE = strWHERE & "F_KUBUN = '" & Trim(strBOX(i)) & "' "
Next
'Where文が生成されたかチェックする
If strWHERE = "Where " Then 'そのままだったら条件文を消す
Response.Write "<b>条件がありませんでした</b><hr>"
strWHERE = "" '条件無しに強引にする
Else
Response.Write "作成した条件[<b>" & strWHERE & "</b>]<hr>"
End If
'表示の関数を呼ぶ(外側に出したかったので)
Call DATA_PRINT(strWHERE)
%>
<HR>
<FORM ACTION="test046-2.asp" METHOD="GET">
<font color="blue">表示させたい区分をチェック(選択)して下さい</font><br>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="ASP">ASP系へのご意見を表示<BR>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="VBA">VBA系へのご意見を表示<BR>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="GUCHI">愚痴系へのご意見を表示<BR>
<INPUT TYPE="CHECKBOX" NAME="KUBUN" VALUE="24H">コンビニ系へのご意見を表示<BR>
<INPUT TYPE="submit" VALUE="送信">←チェック後送信ボタンを押してください
</FORM>
<hr>
関連項目<br>
<A href="test029-1.asp">db029.mdbへデータ追加する</a><br>
</body>
</html>
<% 'パラメータを受け取り、ＳＱＬを発行
Sub DATA_PRINT(strWHERE)
'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
Set db=Server.CreateObject("ADODB.Connection")
'.Provider？プロバイダー？通信会社？じゃなくって
'データアクセスにはJet.OLEDB.4.0を使うことを設定
db.Provider = "Microsoft.Jet.OLEDB.4.0"
'次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
db.ConnectionString = Server.MapPath("db029.mdb")
'やっとデータベースを開ける
db.open
'SQL文を作る
strSQL = "Select * From KANSOU " '感想(KANSOU)テーブルから全項目(*)セレクト
strSQL = strSQL & strWHERE '作成した条件を使用する
strSQL = strSQL & "ORDER BY WriteTime DESC" '並べ替えは時間の降順
'オマケで画面にデータ表示
Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
'お約束のレコードセットの作成 SQL文の発行
Set rs = db.Execute(strSQL)
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しをバカっぽく、そのまま書き込む
Response.Write "<TR>"
Response.Write "<TD>日付</TD>"
Response.Write "<TD>区分</TD>"
Response.Write "<TD>NO.</TD>"
Response.Write "<TD>感想</TD>"
Response.Write "</TR>"
'お約束のＥＯＦまでループは(データが無くなるまでループ)、
Do While rs.EOF = False 'レコードセットの.EOFがFalseの間
Response.Write "<TR>" '内容を表示する、行開始のタグ＜ＴＲ＞
Response.Write "<TD>" & rs.Fields.Item("WriteTime") & "</TD>"
Response.Write "<TD>" & rs.Fields.Item("F_KUBUN") & "</TD>"
If rs.Fields.Item("F_NO") = 0 Then '0の全体かチェック
Response.Write "<TD>全体</TD>"
Else
Response.Write "<TD>" & rs.Fields.Item("F_NO") & "</TD>" 'NO表示
End If
Response.Write "<TD>" & rs.Fields.Item("F_MEMO") & "</TD>"
Response.Write "</TR>"
'次のレコードにポインタを移動する
rs.MoveNext 'これを忘れると悲惨なことに、、、
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
'開いていたレコードセットを閉じる
rs.Close
'データベースも閉じようよ
db.Close
'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
Set db = Nothing
End Sub
%>
| 最近発売の雑誌を紹介する
プログラマーは漫画好き？仕事のじゃまにならない程度に・・・読んでみては？
- 少年ガンガン 2008年 06月号
- つりコミック 2008年 06月号
- 月刊 まんがライフオリジナル 2008年 06月号
- コミックビーム 2008年 06月号
- COMIC B's-LOG (コミックビーズログ) 2008年 06月号
- まんがタイムラブリー 2008年 06月号
- Mystery Sara (ミステリー・サラ) 2008年 06月号
- COMIC 乱 TWINS (ツウィンズ) 2008年 06月号
- 別冊 フレンド 2008年 06月号
|