Classic ASP のテストページです。 情報が古いので参考程度に読んだりテストしてみてください。
三流君(TOP) /ASPで遊ぶ /ASP記事一覧を見る
分類: [Form関係] /DB系ADOを使い( [Mdb接続] [CSV接続] [Excel接続]) /[ASPでTextFileを操作] /[VBScript関数ほか]

Date関数の値を使用してSQL文を作成、当日分をグループ化集計

test039-2.asp
cnt_asp.mdb から訪問されたURLをグループ化して集計、降順に表示
発行する（した）ＳＱＬ文は
Select URL, Count(URL) As URLCNT From log WHERE WriteTime >= #2020/04/03# GROUP BY URL ORDER BY Count(URL) DESC
です
No.URL訪問者
終了です。
cnt_etc.mdb 最近訪問した人のデータ３０件を表示



Dateを使用したサンプル(ソースの紹介)

詳細解説は[http:/asp/backno/asp039.html]を見てください
下記、/cgi-bin/test/test039-2.aspのソース（中身）です

Date を 使った ソースコードを紹介する

表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはDate です。
<%@LANGUAGE=VBScript%>
<html>
<head><META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=x-sjis">
<title>Date関数の値を使用してSQL文を作成、当日分をグループ化集計</title>
</head>
<body>
<h1>Date関数の値を使用してSQL文を作成、当日分をグループ化集計</h1>
test039-2.asp<br>
<hr>
<b>cnt_asp.mdb から訪問されたURLをグループ化して集計、降順に表示</b><br>
<hr>
<%
  'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
  Set db=Server.CreateObject("ADODB.Connection")

  '.Provider？プロバイダー？通信会社？じゃなくって
  'データアクセスにはJet.OLEDB.4.0を使うことを設定
  db.Provider = "Microsoft.Jet.OLEDB.4.0"

  '次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
  db.ConnectionString = Server.MapPath("cnt_asp.mdb")

  'やっとデータベースを開ける
  db.open

  'お約束のレコードセットの作成 テーブル名URLを指定
  'GROUP BY句 で グループ化 Count関数で集計 ORDER BY句で並べ替え
  strSQL = "Select URL, Count(URL) As URLCNT "
  strSQL = strSQL & "From log "
  strSQL = strSQL & "WHERE WriteTime >= #" & Date & "# " '日付は#で囲う
  strSQL = strSQL & "GROUP BY URL "
  strSQL = strSQL & "ORDER BY Count(URL) DESC"

  'オマケで画面にデータ表示
  Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
  Response.Write strSQL & "</font></B><br>です<hr>"

  Set rs = db.Execute(strSQL)

  'データの表示をテーブルで行う
  Response.Write "<TABLE Border='1'>"

  '見出しをバカっぽく、そのまま書き込む
  Response.Write "<TR>"
  Response.Write "<TD>No.</TD>"
  Response.Write "<TD>URL</TD>"
  Response.Write "<TD>訪問者</TD>"
  Response.Write "</TR>"

  'ＥＯＦまでループ
  nCNT = 1
  Do While rs.EOF = False   '.EOFがFalseの間
    Response.Write "<TR>"   '内容を表示する
    Response.Write "<TD>" & nCNT & "</TD>"

    Response.Write "<TD><A HREF='" & rs.Fields.Item("URL") & "' Target='_blank'>"
    Response.Write rs.Fields.Item("URL") & "</A></TD>"

    Response.Write "<TD ALIGN=RIGHT>" & rs.Fields.Item("URLCNT") & "人</TD>"

    Response.Write "</TR>" & Chr(13) & Chr(10)
    '次のレコードにポインタを移動する
    rs.MoveNext    'これを忘れると悲惨なことに、、、
    'カウンタを増やす
    nCNT = nCNT + 1
  Loop

  Response.Write "</TABLE>"  'テーブルは終わりです

  '開いていたレコードセットを閉じる
  rs.Close

  'データベースも閉じようよ
  db.Close

  'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
  Set db = Nothing

%>
<hr>
終了です。<br>
<A HREF="test037-1.asp">cnt_etc.mdb 最近訪問した人のデータ３０件を表示</A><br>
<br>

</body>
</html>


Googleで関連項目を検索する

[キーワード:Date] と サンプル|解説|Dim|Set で検索
↓で検索して他のページも確認してみてください。
Google

あれ？私のページが検索に載ってない（笑）一度お試しを（私のページに、また戻ってきてね（爆））
[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

リンク 三流君 ＡＳＰ系 の 解説を項目ごとにまとめてみました

まぁ、基本はデータの受け取りかなぁ。
・[Form等を使用したデータのやり取り]・・・ASPと言っても、HTMLの入力フォームからデータを受け取ります。POSTやGETでやりとりを押さえますか。

次は、データの入出力 で ADOを使った(ADOで接続) と SQLの解説を少々
・[ADOでMdbファイルを使う]・・・MDBと接続して、簡単な追加・更新・削除を行った。
・[ADOでExcelと接続してみた]・・・.xlsと接続してSQLを使ってみた。
・[ADOでCSVと接続してみた]・・・.CSV テキストを読み出した。※更新・削除はできません

DBが使えるので、あまり使用しないけど、普通のテキストファイル処理
・[テキストファイル処理]・・・ファイルを開いて、書き込む。１行読み込みなどを軽く

VBScriptでFormat関数が無いなど、微妙にVBAと違うけど
[VBScript関数関係の説明]・・・少し、処理を書いてみた。
[その他処理サンプル]・・・あまり良いサンプル作れなかったけど。。。
何かの参考となれば幸いです。

その他：blogや広告↓
[日記的なblog]← あまり更新してないけど・・・
[永遠の下書き日記？]← 恥ずかしいのであまり載せてないけど・・・
[ひとりで掲示板？] ←一人で？掲示板？ぉぃぉぃ

[Topへ戻る] −−＞[ASP系のTOPへ戻る] −−＞[記事一覧を見る]

現在時刻は、2020/04/03 3:28:01です。