GROUP BY を 使った ソースコードを紹介する表示色の説明：ASP VBScriptは <% 〜 %>
キーワードはGROUP BY です。
<%@LANGUAGE=VBScript%>
<html>
<head>
<title>SQL GROUP BY句 で グループ化 Count関数で集計 ORDER BY句で並べ替え</title>
</head>
<body>
<h1>SQL GROUP BY句 で グループ化 Count関数で集計 ORDER BY句で並べ替え</h1>
test039-1.asp<br>
<hr>
<b>cnt_asp.mdb から訪問されたURLをグループ化して集計、降順に表示</b><br>
<hr>
<%
'ADO DB Connection オブジェクトを作成する、英文そのままじゃん
Set db=Server.CreateObject("ADODB.Connection")
'.Provider？プロバイダー？通信会社？じゃなくって
'データアクセスにはJet.OLEDB.4.0を使うことを設定
db.Provider = "Microsoft.Jet.OLEDB.4.0"
'次に、接続ＤＢの位置を渡すので、Server.MapPathで変換して渡す
db.ConnectionString = Server.MapPath("cnt_asp.mdb")
'やっとデータベースを開ける
db.open
'お約束のレコードセットの作成 テーブル名URLを指定
'GROUP BY句 で グループ化 Count関数で集計 ORDER BY句で並べ替え
strSQL = "Select URL, Count(URL) As URLCNT "
strSQL = strSQL & "From log "
strSQL = strSQL & "GROUP BY URL "
strSQL = strSQL & "ORDER BY Count(URL) DESC"
'オマケで画面にデータ表示
Response.Write "<hr>発行する（した）ＳＱＬ文は<br><B><font color='green'>"
Response.Write strSQL & "</font></B><br>です<hr>"
Set rs = db.Execute(strSQL)
'データの表示をテーブルで行う
Response.Write "<TABLE Border='1'>"
'見出しをバカっぽく、そのまま書き込む
Response.Write "<TR>"
Response.Write "<TD>No.</TD>"
Response.Write "<TD>URL</TD>"
Response.Write "<TD>訪問者</TD>"
Response.Write "</TR>"
'ＥＯＦまでループ
nCNT = 1
Do While rs.EOF = False '.EOFがFalseの間
Response.Write "<TR>" '内容を表示する
Response.Write "<TD>" & nCNT & "</TD>"
Response.Write "<TD><A HREF='" & rs.Fields.Item("URL") & "' Target='_blank'>"
Response.Write rs.Fields.Item("URL") & "</A></TD>"
Response.Write "<TD ALIGN=RIGHT>" & rs.Fields.Item("URLCNT") & "人</TD>"
Response.Write "</TR>" & Chr(13) & Chr(10)
'次のレコードにポインタを移動する
rs.MoveNext 'これを忘れると悲惨なことに、、、
'カウンタを増やす
nCNT = nCNT + 1
Loop
Response.Write "</TABLE>" 'テーブルは終わりです
'開いていたレコードセットを閉じる
rs.Close
'データベースも閉じようよ
db.Close
'お行儀よくオブジェクトも開放しましょう（通常は自動的に解放されるけど）
Set db = Nothing
%>
<hr>
終了です。<br>
<A HREF="test037-1.asp">cnt_asp.mdb 最近訪問した人のデータ３０件を表示</A><br>
<br>
</body>
</html>
| 最近発売の雑誌を紹介する
音楽・テレビ・娯楽系の雑誌です。息抜き・息抜き(って、休みすぎ？)
- FLIX JAPAN (フリックス・ジャパン) 2008年 06月号
- 悲劇喜劇 2008年 06月号
- 決定版 ! XX (ダブルエックス) 2008年 06月号
- POTATO (ポテト) 2008年 06月号
- Wink up (ウィンク アップ) 2008年 06月号
- キネマ旬報 2008年 5/15号
- 音楽と人 2008年 06月号
- GALAC (ギャラク) 2008年 06月号
- Duet (デュエット) 2008年 06月号
|