Excel を操作 CreateObject("Excel.Application")

VB,Access から Excel を操作 CreateObject("Excel.Application")

/*
 * ２.VBやAccessからExcelにデータを書き込む
*/
いろいろな場面で、
VBやAccessからExcelを起動し、
データを書き込みたいと思います。

今回は、そんな時のサンプルになれば、、と思い書いてみます。
＊指摘・要望、まってます。

例として、調査したいディレクトリを受け取り、
Ｅｘｃｅｌを起動して、結果を書き込むモジュールを下記に記述します。
* 起動方法 DirListToExcel("C:\windows") など、引数でディレクトリを渡す

----
Public Sub DirListToExcel(strDIR As String)

On Error GoTo Err_DirListToExcel

    Dim MyDirName As String
    Dim MyPath As String
    Dim oApp As Object
    Dim nYLINE As Integer

    '￥を付けるか判断する。
    If Right(Trim(strDIR), 1) <> "\" Then
        strDIR = Trim(strDIR) & "\"  '\を追加する
    End If

    'ディレクトリが存在するか、チェックする。
    If Dir(strDIR, vbDirectory) = "" Then
        MsgBox strDIR & "ディレクトリが見つかりません"
        Exit Sub
    End If
    
    '検索するパターンを渡す
    MyPath = Trim(strDIR)
    MyDirName = Dir(MyPath, vbDirectory)   ' 最初のディレクトリ名を返します。
    If MyDirName = "" Then
        MsgBox "該当ファイルが一件もありません"
        Exit Sub
    End If
    
    'Excel を起動
    ' ↓Accessウイザードで作成されます
    Set oApp = CreateObject("Excel.Application")
    oApp.Visible = True
    'Only XL 97 supports UserControl Property
    On Error Resume Next
    oApp.UserControl = True
    '-------------------------------

    'ここから、がんばって、自分で作成
    oApp.Workbooks.Add '新規のワークシートを追加する
    
    'タイトルを入れる
    oApp.Cells(1, 1) = MyPath & " から下のディレクトリ一覧 " & Date
    
    'ディレクトリの出力
    nYLINE = 2
    Do While MyDirName <> ""   ' ループを開始します。
        ' ビット単位の比較を行い、MyName がフォルダかどうかを調べます。
        If (GetAttr(MyPath & MyDirName) And vbDirectory) = vbDirectory Then
            oApp.Cells(nYLINE, 1) = MyPath & MyDirName    'ディレクトリ名を送信
            nYLINE = nYLINE + 1
        End If
        MyDirName = Dir    ' 次のディレクトリ名を返します。
    Loop

    Set oApp = Nothing

Exit_DirListToExcel:
    Exit Sub

Err_DirListToExcel:
    MsgBox Err.Description
    Resume Exit_DirListToExcel

End Sub
----

/*
 * ３．Excel起動解説
*/

Access,VB 同じ関数で動くみたいなので、
共通して、説明します。

まず、Ｅｘｃｅｌの起動方法です。

    Dim oApp As Object
で、操作用の変数を確保します

    Set oApp = CreateObject("Excel.Application")
    oApp.Visible = True
    'Only XL 97 supports UserControl Property
    On Error Resume Next
    oApp.UserControl = True

CreateObjectを使用し、エクセルのオブジェクトを作成します。
何いってんの、、英単語翻訳しただけジャン？
まぁまぁ、、

oApp.Visible = True で見えるようにして、、、
oApp.UserControl = True でユーザーが操作可能に、、

なんか、自信なさそうだけど、、？

はい、実は、Ａｃｃｅｓｓのボタンのウイザードで作成してくれるんですよ。。

あっ、そうなの。
じゃ、Ｅｘｃｅｌを操作するときの決り文句で知っとけばいいの？

ホントは、知らないと、Ｗｏｒｄの時は、、など、応用できないので、、、
わかりやすい資料見つけたら、また、解説します。

/*
 * ４．Excelを操作する
*/
Excelの起動が無事にできたところで、
次に、Excelを操作するには？
です。

oApp.Workbooks.Add '新規のワークシートを追加する
で新規のブックを追加します。
    
'タイトルを入れる
oApp.Cells(1, 1) = MyPath & " から下のディレクトリ一覧 " & Date
セルのＡ1（1，1の座標）にタイトルを入れます。

oApp.Cells(nYLINE, 1) = MyPath & MyDirName    'ディレクトリ名を送信
.Cells(Y, X) でデータをＹ行Ｘ列に入れることができます。

解説途中で悪いけど、
なんで、Workbooks.Add は、新規ブックの追加、
Cells(1, 1)は、、、って知ったの？どこみるの？

えっとですね、下準備で、Ｅｘｃｅｌを起動して、
ツール・マクロの記録で記録して、
それをヘルプで調べたんですよ。

Ｅｘｃｅｌのオブジェクト体系がわかってくると、いろいろできますよ。
（楽しいですよ）

それをもっと知りたいんだけど、、なぁ。。

今回は、
Workbooks.Add と Cells(Y, X) で、、、落ち着いたら、いろいろやりましょう。

じゃ、次回以降って約束で、、、

枠外解説・グチ --- 行儀が悪い書き方です

oApp.Cells(nYLINE, 1) = XXXX
って書き方、行儀が悪い書き方です。
オブジェクト.ブック.シート.セル　が よい書き方です。
ＥｘｃｅｌのＶＢＡをやるときに、詳しく、解説したいと思います。

/*
 * ５．おわりの挨拶
*/
なんとなく？わかりましたか？（楽しめましたか？）
処理結果をＥｘｃｅｌに出力できると、
意外と便利なので、この機会に、、おぼえていただけると、、

オマエの教え方がイマイチ、、だよ、、

そうですか、、、次回はビシット、、なんてね。

マクロ記録




ブックの新規作成ボタンを押す。


マクロの記録を停止し、
Alt+F11で記録されたモジュールを見る


ここれをみて、　.ａｄｄを勉強する？

サンプル実行結果

VBA系の無料メルマガ書いてます
メルマガ『ＶＢＡで楽しくプログラミング』(無料) を購読しませんか？
	E-mail

ＶＢＡで楽しくプログラミング	最新情報	掲示板	バックナンバー	メルマガ登録と解除
コンビニのオモテとウラ話	最新情報	掲示板	バックナンバー	メルマガ登録と解除
ＡＳＰで遊ぶ、失敗する	最新情報	掲示板	バックナンバー	メルマガ登録と解除
AB型三流ＰＧ 業務のグチ	最新情報	掲示板	バックナンバー	メルマガ登録と解除
初心者にやさしいプログラム	最新情報	掲示板	バックナンバー	メルマガ登録と解除
ネットで稼ぐ本音と失敗談	最新情報	掲示板	バックナンバー
www.ken3.org(サイト内)から を利用して、 を